Terraform এবং Firebase দিয়ে শুরু করুন

এই উদাহরণ কনফিগার ফাইলের একটি উচ্চ টীকা সংস্করণ দেখুন

আপনি যদি সম্পদ হিসাবে প্রকল্প এবং অ্যাপ্লিকেশনগুলির পরিকাঠামোর সাথে পরিচিত না হন তবে নিম্নলিখিত ডকুমেন্টেশনগুলি পর্যালোচনা করুন:

• ফায়ারবেস প্রকল্পগুলি বুঝুন
• ফায়ারবেস প্রকল্প পরিচালনার জন্য রেফারেন্স ডকুমেন্টেশন

# Terraform configuration to set up providers by version.
...

# Configures the provider to use the resource block's specified project for quota checks.
...

# Configures the provider to not use the resource block's specified project for quota checks.
...

# Creates a new Google Cloud project.
resource "google_project" "default" {
  # Use the provider that enables the setup of quota checks for a new project
  provider   = google-beta.no_user_project_override

  name            = "Project Display Name"        // learn more about the project name
  project_id      = "project-id-for-new-project"  // learn more about the project ID
  # Required for any service that requires the Blaze pricing plan
  # (like Firebase Authentication with GCIP)
  billing_account = "000000-000000-000000"

  # Required for the project to display in any list of Firebase projects.
  labels = {
    "firebase" = "enabled"  // learn more about the Firebase-enabled label
  }
}

# Enables required APIs.
resource "google_project_service" "default" {
  # Use the provider without quota checks for enabling APIS
  provider = google-beta.no_user_project_override
  project  = google_project.default.project_id
  for_each = toset([
    "cloudbilling.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "firebase.googleapis.com",
    # Enabling the ServiceUsage API allows the new project to be quota checked from now on.
    "serviceusage.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
# This action essentially "creates a Firebase project" and allows the project to use
# Firebase services (like Firebase Authentication) and
# Firebase tooling (like the Firebase console).
# Learn more about the relationship between Firebase projects and Google Cloud.
resource "google_firebase_project" "default" {
  # Use the provider that performs quota checks from now on
  provider = google-beta

  project  = google_project.default.project_id

  # Waits for the required APIs to be enabled.
  depends_on = [
    google_project_service.default
  ]
}

# Creates a Firebase Android App in the new project created above.
# Learn more about the relationship between Firebase Apps and Firebase projects.
resource "google_firebase_android_app" "default" {
  provider = google-beta

  project      = google_project.default.project_id
  display_name = "My Awesome Android app"  # learn more about an app's display name
  package_name = "awesome.package.name"    # learn more about an app's package name

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.default,
  ]
}

GCIP এর সাথে Firebase প্রমাণীকরণ সেট আপ করুন

এই কনফিগারেশনটি একটি নতুন Google ক্লাউড প্রকল্প তৈরি করে, একটি ক্লাউড বিলিং অ্যাকাউন্টের সাথে প্রকল্পটিকে সংযুক্ত করে (GCIP এর সাথে Firebase প্রমাণীকরণের জন্য Blaze মূল্য পরিকল্পনা প্রয়োজন), প্রকল্পের জন্য Firebase পরিষেবাগুলি সক্ষম করে, GCIP এর সাথে Firebase প্রমাণীকরণ সেট আপ করে এবং তিনটি ভিন্ন অ্যাপ নিবন্ধন করে প্রকল্পের সাথে প্রকার।

মনে রাখবেন যে টেরাফর্মের মাধ্যমে ফায়ারবেস প্রমাণীকরণ সেট আপ করতে GCIP সক্ষম করা প্রয়োজন।

# Creates a new Google Cloud project.
resource "google_project" "auth" {
  provider  = google-beta.no_user_project_override
  folder_id = "folder-id-for-new-project"
  name            = "Project Display Name"
  project_id      = "project-id-for-new-project"

  # Associates the project with a Cloud Billing account
  # (required for Firebase Authentication with GCIP).
  billing_account = "000000-000000-000000"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "auth" {
  provider = google-beta.no_user_project_override
  project  = google_project.auth.project_id
  for_each = toset([
    "cloudbilling.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "serviceusage.googleapis.com",
    "identitytoolkit.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "auth" {
  provider = google-beta
  project  = google_project.auth.project_id

  depends_on = [
    google_project_service.auth,
  ]
}

# Creates an Identity Platform config.
# Also enables Firebase Authentication with Identity Platform in the project if not.
resource "google_identity_platform_config" "auth" {
  provider = google-beta
  project  = google_project.auth.project_id

  # Auto-deletes anonymous users
  autodelete_anonymous_users = true

  # Configures local sign-in methods, like anonymous, email/password, and phone authentication.
  sign_in {
    allow_duplicate_emails = true

    anonymous {
      enabled = true
    }

    email {
      enabled = true
      password_required = false
    }

    phone_number {
      enabled = true
      test_phone_numbers = {
        "+11231231234" = "000000"
      }
    }
  }

  # Sets an SMS region policy.
  sms_region_config {
    allowlist_only {
      allowed_regions = [
        "US",
        "CA",
      ]
    }
  }

  # Configures blocking functions.
  blocking_functions {
    triggers {
      event_type = "beforeSignIn"
      function_uri = "https://us-east1-${google_project.auth.project_id}.cloudfunctions.net/before-sign-in"
    }
    forward_inbound_credentials {
      refresh_token = true
      access_token = true
      id_token = true
    }
  }

  # Configures a temporary quota for new signups for anonymous, email/password, and phone number.
  quota {
    sign_up_quota_config {
      quota = 1000
      start_time = ""
      quota_duration = "7200s"
    }
  }

  # Configures authorized domains.
  authorized_domains = [
    "localhost",
    "${google_project.auth.project_id}.firebaseapp.com",
    "${google_project.auth.project_id}.web.app",
  ]

  # Wait for identitytoolkit.googleapis.com to be enabled before initializing Authentication.
  depends_on = [
    google_project_service.auth,
  ]
}

# Creates a Firebase Android App in the new project created above.
resource "google_firebase_android_app" "auth" {
  provider     = google-beta
  project      = google_project.auth.project_id
  display_name = "My Android app"
  package_name = "android.package.name"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.auth,
  ]
}

# Creates a Firebase Apple-platforms App in the new project created above.
resource "google_firebase_apple_app" "auth" {
  provider     = google-beta
  project      = google_project.auth.project_id
  display_name = "My Apple app"
  bundle_id    = "apple.app.12345"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.auth,
  ]
}

# Creates a Firebase Web App in the new project created above.
resource "google_firebase_web_app" "auth" {
  provider     = google-beta
  project      = google_project.auth.project_id
  display_name = "My Web app"

  # The other App types (Android and Apple) use "DELETE" by default.
  # Web apps don't use "DELETE" by default due to backward-compatibility.
  deletion_policy = "DELETE"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.auth,
  ]
}

ডিফল্ট ফায়ারবেস রিয়েলটাইম ডেটাবেস উদাহরণ প্রদান করুন

এই কনফিগারেশনটি একটি নতুন Google ক্লাউড প্রকল্প তৈরি করে, প্রকল্পের জন্য ফায়ারবেস পরিষেবাগুলিকে সক্ষম করে, প্রকল্পের ডিফল্ট রিয়েলটাইম ডেটাবেস উদাহরণের বিধান করে এবং প্রকল্পের সাথে তিনটি ভিন্ন ধরনের অ্যাপ নিবন্ধন করে৷

# Creates a new Google Cloud project.
resource "google_project" "rtdb" {
  provider   = google-beta.no_user_project_override
  folder_id  = "folder-id-for-new-project"
  name       = "Project Display Name"
  project_id = "project-id-for-new-project"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "rtdb" {
  provider = google-beta.no_user_project_override
  project  = google_project.rtdb.project_id
  for_each = toset([
    "serviceusage.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "firebasedatabase.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "rtdb" {
  provider = google-beta
  project  = google_project.rtdb.project_id
}

# Provisions the default Realtime Database default instance.
resource "google_firebase_database_instance" "database" {
  provider    = google-beta
  project     = google_project.rtdb.project_id
  # See available locations: https://firebase.google.com/docs/projects/locations#rtdb-locations
  region      = "name-of-region"
  # This value will become the first segment of the database's URL.
  instance_id = "${google_project.rtdb.project_id}-default-rtdb"
  type        = "DEFAULT_DATABASE"

  # Wait for Firebase to be enabled in the Google Cloud project before initializing Realtime Database.
  depends_on = [
    google_firebase_project.rtdb,
  ]
}

# Creates a Firebase Android App in the new project created above.
resource "google_firebase_android_app" "rtdb" {
  provider     = google-beta
  project      = google_project.rtdb.project_id
  display_name = "My Android app"
  package_name = "android.package.name"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.rtdb,
  ]
}

# Creates a Firebase Apple-platforms App in the new project created above.
resource "google_firebase_apple_app" "rtdb" {
  provider     = google-beta
  project      = google_project.rtdb.project_id
  display_name = "My Apple app"
  bundle_id    = "apple.app.12345"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.rtdb,
  ]
}

# Creates a Firebase Web App in the new project created above.
resource "google_firebase_web_app" "rtdb" {
  provider     = google-beta
  project      = google_project.rtdb.project_id
  display_name = "My Web app"

  # The other App types (Android and Apple) use "DELETE" by default.
  # Web apps don't use "DELETE" by default due to backward-compatibility.
  deletion_policy = "DELETE"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.rtdb,
  ]
}

একাধিক ফায়ারবেস রিয়েলটাইম ডেটাবেস উদাহরণ প্রদান করুন

এই কনফিগারেশনটি একটি নতুন Google ক্লাউড প্রকল্প তৈরি করে, একটি ক্লাউড বিলিং অ্যাকাউন্টের সাথে প্রকল্পটিকে সংযুক্ত করে (একাধিক রিয়েলটাইম ডেটাবেস দৃষ্টান্তের জন্য ব্লেজ মূল্য পরিকল্পনা প্রয়োজন), প্রকল্পের জন্য ফায়ারবেস পরিষেবাগুলি সক্ষম করে, একাধিক রিয়েলটাইম ডেটাবেস উদাহরণের (প্রজেক্টের ডিফল্ট রিয়েলটাইম ডেটাবেস সহ) ব্যবস্থা করে উদাহরণ), এবং প্রকল্পের সাথে তিনটি ভিন্ন অ্যাপের প্রকার নিবন্ধন করে।

# Creates a new Google Cloud project.
resource "google_project" "rtdb-multi" {
  provider   = google-beta.no_user_project_override
  folder_id  = "folder-id-for-new-project"
  name       = "Project Display Name"
  project_id = "project-id-for-new-project"

  # Associate the project with a Cloud Billing account
  # (required for multiple Realtime Database instances).
  billing_account = "000000-000000-000000"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "rtdb-multi" {
  provider = google-beta.no_user_project_override
  project  = google_project.rtdb-multi.project_id
  for_each = toset([
    "cloudbilling.googleapis.com",
    "serviceusage.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "firebasedatabase.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "rtdb-multi" {
  provider = google-beta
  project  = google_project.rtdb-multi.project_id
}

# Provisions the default Realtime Database default instance.
resource "google_firebase_database_instance" "database-default" {
  provider    = google-beta
  project     = google_project.rtdb-multi.project_id
  # See available locations: https://firebase.google.com/docs/projects/locations#rtdb-locations
  region      = "name-of-region"
  # This value will become the first segment of the database's URL.
  instance_id = "${google_project.rtdb-multi.project_id}-default-rtdb"
  type        = "DEFAULT_DATABASE"

  # Wait for Firebase to be enabled in the Google Cloud project before initializing Realtime Database.
  depends_on = [
    google_firebase_project.rtdb-multi,
  ]
}

# Provisions an additional Realtime Database instance.
resource "google_firebase_database_instance" "database-additional" {
  provider    = google-beta
  project     = google_project.rtdb-multi.project_id
  # See available locations: https://firebase.google.com/docs/projects/locations#rtdb-locations
  # This location doesn't need to be the same as the default database instance.
  region      = "name-of-region"
  # This value will become the first segment of the database's URL.
  instance_id = "name-of-additional-database-instance"
  type        = "USER_DATABASE"

  # Wait for Firebase to be enabled in the Google Cloud project before initializing Realtime Database.
  depends_on = [
    google_firebase_project.rtdb-multi,
  ]
}

# Creates a Firebase Android App in the new project created above.
resource "google_firebase_android_app" "rtdb-multi" {
  provider     = google-beta
  project      = google_project.rtdb-multi.project_id
  display_name = "My Android app"
  package_name = "android.package.name"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.rtdb-multi,
  ]
}

# Creates a Firebase Apple-platforms App in the new project created above.
resource "google_firebase_apple_app" "rtdb-multi" {
  provider     = google-beta
  project      = google_project.rtdb-multi.project_id
  display_name = "My Apple app"
  bundle_id    = "apple.app.12345"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.rtdb-multi,
  ]
}

# Creates a Firebase Web App in the new project created above.
resource "google_firebase_web_app" "rtdb-multi" {
  provider     = google-beta
  project      = google_project.rtdb-multi.project_id
  display_name = "My Web app"

  # The other App types (Android and Apple) use "DELETE" by default.
  # Web apps don't use "DELETE" by default due to backward-compatibility.
  deletion_policy = "DELETE"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.rtdb-multi,
  ]
}

ক্লাউড ফায়ারস্টোর উদাহরণ প্রদান করুন

এই কনফিগারেশনটি একটি নতুন Google ক্লাউড প্রকল্প তৈরি করে, প্রকল্পের জন্য ফায়ারবেস পরিষেবাগুলি সক্ষম করে, প্রকল্পের ক্লাউড ফায়ারস্টোর দৃষ্টান্তের বিধান করে এবং প্রকল্পের সাথে তিনটি ভিন্ন ধরনের অ্যাপ নিবন্ধন করে৷

এটি ক্লাউড ফায়ারস্টোর দৃষ্টান্তের জন্য ফায়ারবেস নিরাপত্তা বিধি বিধান করে, একটি ক্লাউড ফায়ারস্টোর সূচক তৈরি করে এবং বীজ ডেটা সহ একটি ক্লাউড ফায়ারস্টোর নথি যোগ করে।

# Creates a new Google Cloud project.
resource "google_project" "firestore" {
  provider   = google-beta.no_user_project_override
  folder_id  = "folder-id-for-new-project"
  name       = "Project Display Name"
  project_id = "project-id-for-new-project"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "firestore" {
  provider = google-beta.no_user_project_override
  project  = google_project.firestore.project_id
  for_each = toset([
    "cloudresourcemanager.googleapis.com",
    "serviceusage.googleapis.com",
    "firestore.googleapis.com",
    "firebaserules.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "firestore" {
  provider = google-beta
  project  = google_project.firestore.project_id
}

# Provisions the Firestore database instance.
resource "google_firestore_database" "firestore" {
  provider                    = google-beta
  project                     = google_project.firestore.project_id
  name                        = "(default)"
  # See available locations: https://firebase.google.com/docs/projects/locations#default-cloud-location
  location_id                 = "name-of-region"
  # "FIRESTORE_NATIVE" is required to use Firestore with Firebase SDKs, authentication, and Firebase Security Rules.
  type                        = "FIRESTORE_NATIVE"
  concurrency_mode            = "OPTIMISTIC"

  # Wait for Firebase to be enabled in the Google Cloud project before initializing Firestore.
  depends_on = [
    google_firebase_project.firestore,
  ]
}

# Creates a ruleset of Firestore Security Rules from a local file.
resource "google_firebaserules_ruleset" "firestore" {
  provider = google-beta
  project  = google_project.firestore.project_id
  source {
    files {
      name = "firestore.rules"
      # Write security rules in a local file named "firestore.rules".
      # Learn more: https://firebase.google.com/docs/firestore/security/get-started
      content = file("firestore.rules")
    }
  }

  # Wait for Firestore to be provisioned before creating this ruleset.
  depends_on = [
    google_firestore_database.firestore,
  ]
}

# Releases the ruleset for the Firestore instance.
resource "google_firebaserules_release" "firestore" {
  provider     = google-beta
  name         = "cloud.firestore"  # must be cloud.firestore
  ruleset_name = google_firebaserules_ruleset.firestore.name
  project      = google_project.firestore.project_id

  # Wait for Firestore to be provisioned before releasing the ruleset.
  depends_on = [
    google_firestore_database.firestore,
  ]
}

# Adds a new Firestore index.
resource "google_firestore_index" "indexes" {
  provider = google-beta
  project  = google_project.firestore.project_id

  collection  = "quiz"
  query_scope = "COLLECTION"

  fields {
    field_path = "question"
    order      = "ASCENDING"
  }

  fields {
    field_path = "answer"
    order      = "ASCENDING"
  }

  # Wait for Firestore to be provisioned before adding this index.
  depends_on = [
    google_firestore_database.firestore,
  ]
}

# Adds a new Firestore document with seed data.
# Don't use real end-user or production data in this seed document.
resource "google_firestore_document" "doc" {
  provider    = google-beta
  project     = google_project.firestore.project_id
  collection  = "quiz"
  document_id = "question-1"
  fields      = "{\"question\":{\"stringValue\":\"Favorite Database\"},\"answer\":{\"stringValue\":\"Firestore\"}}"

  # Wait for Firestore to be provisioned before adding this document.
  depends_on = [
    google_firestore_database.firestore,
  ]
}

# Creates a Firebase Android App in the new project created above.
resource "google_firebase_android_app" "firestore" {
  provider     = google-beta
  project      = google_project.firestore.project_id
  display_name = "My Android app"
  package_name = "android.package.name"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.firestore,
  ]
}

# Creates a Firebase Apple-platforms App in the new project created above.
resource "google_firebase_apple_app" "firestore" {
  provider     = google-beta
  project      = google_project.firestore.project_id
  display_name = "My Apple app"
  bundle_id    = "apple.app.12345"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.firestore,
  ]
}

# Creates a Firebase Web App in the new project created above.
resource "google_firebase_web_app" "firestore" {
  provider     = google-beta
  project      = google_project.firestore.project_id
  display_name = "My Web app"

  # The other App types (Android and Apple) use "DELETE" by default.
  # Web apps don't use "DELETE" by default due to backward-compatibility.
  deletion_policy = "DELETE"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.firestore,
  ]
}

এটি হল ক্লাউড ফায়ারস্টোর নিরাপত্তা বিধির নিয়ম যা firestore.rules নামে একটি স্থানীয় ফাইলে থাকা উচিত।

rules_version = '2';
service cloud.firestore {
  match /databases/{database}/documents {
    allow read: if request.auth != null;
    allow create: if request.auth != null;
    allow update: if request.auth != null;
  }
}

ডিফল্ট ক্লাউড স্টোরেজ বাকেটের ব্যবস্থা করুন

এই কনফিগারেশনটি একটি নতুন Google ক্লাউড প্রকল্প তৈরি করে, প্রকল্পের জন্য ফায়ারবেস পরিষেবাগুলিকে সক্ষম করে, প্রকল্পের ডিফল্ট ক্লাউড স্টোরেজ বাকেটের বিধান করে এবং প্রকল্পের সাথে তিনটি ভিন্ন ধরনের অ্যাপ নিবন্ধন করে৷

এটি ক্লাউড স্টোরেজ বাকেটের জন্য ফায়ারবেস নিরাপত্তা নিয়মেরও ব্যবস্থা করে এবং বালতিতে একটি ফাইল আপলোড করে।

# Creates a new Google Cloud project.
resource "google_project" "storage" {
  provider   = google-beta.no_user_project_override
  folder_id  = "folder-id-for-new-project"
  name       = "Project Display Name"
  project_id = "project-id-for-new-project"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "storage" {
  provider = google-beta.no_user_project_override
  project  = google_project.storage.project_id
  for_each = toset([
    "serviceusage.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "firebaserules.googleapis.com",
    "firebasestorage.googleapis.com",
    "storage.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "storage" {
  provider = google-beta
  project  = google_project.storage.project_id
}

# Provisions the default Cloud Storage bucket for the project via Google App Engine.
resource "google_app_engine_application" "default" {
  provider    = google-beta
  project     = google_project.storage.project_id
  # See available locations: https://firebase.google.com/docs/projects/locations#default-cloud-location
  # This will set the location for the default Storage bucket and the App Engine App.
  location_id = "name-of-region-for-default-bucket"

  # If you use Firestore, uncomment this to make sure Firestore is provisioned first.
  # depends_on = [
    # google_firestore_database.firestore
  # ]
}

# Makes the default Storage bucket accessible for Firebase SDKs, authentication, and Firebase Security Rules.
resource "google_firebase_storage_bucket" "default-bucket" {
  provider  = google-beta
  project   = google_project.storage.project_id
  bucket_id = google_app_engine_application.default.default_bucket
}

# Creates a ruleset of Cloud Storage Security Rules from a local file.
resource "google_firebaserules_ruleset" "storage" {
  provider = google-beta
  project  = google_project.storage.project_id
  source {
    files {
      # Write security rules in a local file named "storage.rules".
      # Learn more: https://firebase.google.com/docs/storage/security/get-started
      name    = "storage.rules"
      content = file("storage.rules")
    }
  }

  # Wait for the default Storage bucket to be provisioned before creating this ruleset.
  depends_on = [
    google_firebase_project.storage,
  ]
}

# Releases the ruleset to the default Storage bucket.
resource "google_firebaserules_release" "default-bucket" {
  provider     = google-beta
  name         = "firebase.storage/${google_app_engine_application.default.default_bucket}"
  ruleset_name = "projects/${google_project.storage.project_id}/rulesets/${google_firebaserules_ruleset.storage.name}"
  project      = google_project.storage.project_id
}

# Uploads a new file to the default Storage bucket.
# Don't use real end-user or production data in this file.
resource "google_storage_bucket_object" "cat-picture" {
  provider = google-beta
  name     = "cat.png"
  source   = "path/to/cat.png"
  bucket   = google_app_engine_application.default.default_bucket
}

# Creates a Firebase Android App in the new project created above.
resource "google_firebase_android_app" "storage" {
  provider     = google-beta
  project      = google_project.storage.project_id
  display_name = "My Android app"
  package_name = "android.package.name"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.storage,
  ]
}

# Creates a Firebase Apple-platforms App in the new project created above.
resource "google_firebase_apple_app" "storage" {
  provider     = google-beta
  project      = google_project.storage.project_id
  display_name = "My Apple app"
  bundle_id    = "apple.app.12345"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.storage,
  ]
}

# Creates a Firebase Web App in the new project created above.
resource "google_firebase_web_app" "storage" {
  provider     = google-beta
  project      = google_project.storage.project_id
  display_name = "My Web app"

  # The other App types (Android and Apple) use "DELETE" by default.
  # Web apps don't use "DELETE" by default due to backward-compatibility.
  deletion_policy = "DELETE"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.storage,
  ]
}

এটি হল ক্লাউড স্টোরেজ সিকিউরিটি রুলসের রুলসেট যা storage.rules নামে একটি স্থানীয় ফাইলে থাকা উচিত।

rules_version = '2';
service firebase.storage {
  match /b/{bucket}/o {
    match /{allPaths=**} {
      allow read, write: if request.auth != null;
    }
  }
}

একাধিক ক্লাউড স্টোরেজ বালতি সরবরাহ করুন

এই কনফিগারেশনটি একটি নতুন Google ক্লাউড প্রকল্প তৈরি করে, একটি ক্লাউড বিলিং অ্যাকাউন্টের সাথে প্রকল্পটিকে সংযুক্ত করে (একাধিক বালতির জন্য ব্লেজ মূল্য পরিকল্পনা প্রয়োজন), প্রকল্পের জন্য ফায়ারবেস পরিষেবাগুলি সক্ষম করে, একাধিক ক্লাউড স্টোরেজ বালতি (প্রকল্পের ডিফল্ট ক্লাউড স্টোরেজ বালতি সহ) বিধান করে , এবং প্রকল্পের সাথে তিনটি ভিন্ন ধরনের অ্যাপ নিবন্ধন করে।

এটি ক্লাউড স্টোরেজ বালতিগুলির জন্য ফায়ারবেস সুরক্ষা নিয়মগুলিও সরবরাহ করে এবং ডিফল্ট ক্লাউড স্টোরেজ বালতিতে একটি ফাইল আপলোড করে৷

# Creates a new Google Cloud project.
resource "google_project" "storage-multi" {
  provider  = google-beta.no_user_project_override
  folder_id = "folder-id-for-new-project"
  name            = "Project Display Name"
  project_id      = "project-id-for-new-project"

  # Associates the project with a Cloud Billing account
  # (required for multiple Cloud Storage buckets).
  billing_account = "000000-000000-000000"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "storage-multi" {
  provider = google-beta.no_user_project_override
  project  = google_project.storage-multi.project_id
  for_each = toset([
    "cloudbilling.googleapis.com",
    "serviceusage.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "firebaserules.googleapis.com",
    "firebasestorage.googleapis.com",
    "storage.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "storage-multi" {
  provider = google-beta
  project  = google_project.storage-multi.project_id
}

# Provisions the default Cloud Storage bucket for the project via Google App Engine.
resource "google_app_engine_application" "default-multi" {
  provider = google-beta
  project  = google_project.storage-multi.project_id
  # See available locations: https://firebase.google.com/docs/projects/locations#default-cloud-location
  # This will set the location for the default Storage bucket and the App Engine App.
  location_id = "name-of-region-for-default-bucket"

  # If you use Firestore, uncomment this to make sure Firestore is provisioned first.
  # depends_on = [
  # google_firestore_database.firestore
  # ]
}

# Provisions an additional Cloud Storage bucket.
# Additional Cloud Storage buckets are not provisioned via App Engine.
resource "google_storage_bucket" "bucket-multi" {
  provider = google-beta
  project  = google_project.storage-multi.project_id
  name     = "name-of-additional-storage-bucket"
  # See available locations: https://cloud.google.com/storage/docs/locations#available-locations
  # This location does not need to be the same as the default Storage bucket.
  location = "name-of-region-for-additional-bucket"
}

# Makes the default Storage bucket accessible for Firebase SDKs, authentication, and Firebase Security Rules.
resource "google_firebase_storage_bucket" "default-bucket-multi" {
  provider  = google-beta
  project   = google_project.storage-multi.project_id
  bucket_id = google_app_engine_application.default-multi.default_bucket
}

# Makes the additional Storage bucket accessible for Firebase SDKs, authentication, and Firebase Security Rules.
resource "google_firebase_storage_bucket" "bucket-multi" {
  provider  = google-beta
  project   = google_project.storage-multi.project_id
  bucket_id = google_storage_bucket.bucket-multi.name
}

# Creates a ruleset of Firebase Security Rules from a local file.
resource "google_firebaserules_ruleset" "storage-multi" {
  provider = google-beta
  project  = google_project.storage-multi.project_id
  source {
    files {
      # Write security rules in a local file named "storage.rules"
      # Learn more: https://firebase.google.com/docs/storage/security/get-started
      name    = "storage.rules"
      content = file("storage.rules")
    }
  }

  # Wait for the Storage buckets to be provisioned before creating this ruleset.
  depends_on = [
    google_firebase_project.storage-multi,
  ]
}

# Releases the ruleset to the default Storage bucket.
resource "google_firebaserules_release" "default-bucket-multi" {
  provider     = google-beta
  name         = "firebase.storage/${google_app_engine_application.default-multi.default_bucket}"
  ruleset_name = "projects/${google_project.storage-multi.project_id}/rulesets/${google_firebaserules_ruleset.storage-multi.name}"
  project      = google_project.storage-multi.project_id
}

# Releases the ruleset to the additional Storage bucket.
resource "google_firebaserules_release" "bucket-multi" {
  provider     = google-beta
  name         = "firebase.storage/${google_storage_bucket.bucket-multi.name}"
  ruleset_name = "projects/${google_project.storage-multi.project_id}/rulesets/${google_firebaserules_ruleset.storage-multi.name}"
  project      = google_project.storage-multi.project_id
}

# Uploads a new file to the default Storage bucket.
# Do not use real end-user or production data in this file.
resource "google_storage_bucket_object" "cat-picture-multi" {
  provider = google-beta
  name     = "cat.png"
  source   = "path/to/cat.png"
  bucket   = google_app_engine_application.default-multi.default_bucket
}

# Creates a Firebase Android App in the new project created above.
resource "google_firebase_android_app" "storage-multi" {
  provider     = google-beta
  project      = google_project.storage-multi.project_id
  display_name = "My Android app"
  package_name = "android.package.name"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.storage-multi,
  ]
}

# Creates a Firebase Apple-platforms App in the new project created above.
resource "google_firebase_apple_app" "storage-multi" {
  provider     = google-beta
  project      = google_project.storage-multi.project_id
  display_name = "My Apple app"
  bundle_id    = "apple.app.12345"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.storage-multi,
  ]
}

# Creates a Firebase Web App in the new project created above.
resource "google_firebase_web_app" "storage-multi" {
  provider     = google-beta
  project      = google_project.storage-multi.project_id
  display_name = "My Web app"

  # The other App types (Android and Apple) use "DELETE" by default.
  # Web apps don't use "DELETE" by default due to backward-compatibility.
  deletion_policy = "DELETE"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.storage-multi,
  ]
}

এটি হল ক্লাউড স্টোরেজ সিকিউরিটি রুলসের রুলসেট যা storage.rules নামে একটি স্থানীয় ফাইলে থাকা উচিত।

rules_version = '2';
service firebase.storage {
  match /b/{bucket}/o {
    match /{allPaths=**} {
      allow read, write: if request.auth != null;
    }
  }
}

ক্লাউড ফায়ারস্টোর ইনস্ট্যান্স এবং ডিফল্ট ক্লাউড স্টোরেজ বাকেটের ব্যবস্থা করুন

এই কনফিগারেশনটি একটি নতুন Google ক্লাউড প্রকল্প তৈরি করে, প্রকল্পের জন্য ফায়ারবেস পরিষেবাগুলি সক্ষম করে, ক্লাউড ফায়ারস্টোর দৃষ্টান্তের বিধান করে এবং তারপরে ডিফল্ট ক্লাউড স্টোরেজ বাকেটের ব্যবস্থা করে৷

এটি ক্লাউড ফায়ারস্টোর ইনস্ট্যান্স এবং ডিফল্ট ক্লাউড স্টোরেজ বাকেটের জন্য ফায়ারবেস নিরাপত্তা নিয়মেরও ব্যবস্থা করে।

# Creates a new Google Cloud project.
resource "google_project" "fs" {  # fs = Firestore + Storage
  provider   = google-beta.no_user_project_override
  folder_id  = "folder-id-for-new-project"
  name       = "Project Display Name"
  project_id = "project-id-for-new-project"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "fs" {
  provider = google-beta.no_user_project_override
  project  = google_project.fs.project_id
  for_each = toset([
    "serviceusage.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "firebaserules.googleapis.com",
    "firebasestorage.googleapis.com",
    "storage.googleapis.com",
    "firestore.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "fs" {
  provider = google-beta
  project  = google_project.fs.project_id

}

#### Set up Firestore before default Cloud Storage bucket ####

# Provisions the Firestore database instance.
resource "google_firestore_database" "firestore-fs" {
  provider         = google-beta
  project          = google_project.fs.project_id
  name             = "(default)"
  # See available locations: https://firebase.google.com/docs/projects/locations#default-cloud-location
  location_id      = "name-of-region"
  # "FIRESTORE_NATIVE" is required to use Firestore with Firebase SDKs, authentication, and Firebase Security Rules.
  type             = "FIRESTORE_NATIVE"
  concurrency_mode = "OPTIMISTIC"

  # Wait for Firebase to be enabled in the Google Cloud project before initializing Firestore.
  depends_on = [
    google_firebase_project.fs,
  ]
}

# Creates a ruleset of Firestore Security Rules from a local file.
resource "google_firebaserules_ruleset" "firestore-fs" {
  provider = google-beta
  project  = google_project.fs.project_id
  source {
    files {
      # Write security rules in a local file named "firestore.rules".
      # Learn more: https://firebase.google.com/docs/firestore/security/get-started
      name = "firestore.rules"
      content = file("firestore.rules")
    }
  }

  # Wait for Firestore to be provisioned before creating this ruleset.
  depends_on = [
    google_firestore_database.firestore-fs
  ]
}

# Releases the ruleset for the Firestore instance.
resource "google_firebaserules_release" "firestore-fs" {
  provider     = google-beta
  name         = "cloud.firestore" # must be cloud.firestore
  ruleset_name = google_firebaserules_ruleset.firestore-fs.name
  project      = google_project.fs.project_id

  # Wait for Firestore to be provisioned before releasing the ruleset.
  depends_on = [
    google_firestore_database.firestore-fs,
  ]
}

#### Set up default Cloud Storage default bucket after Firestore ####

# Provisions the default Cloud Storage bucket for the project via Google App Engine.
resource "google_app_engine_application" "default-bucket-fs" {
  provider    = google-beta
  project     = google_project.fs.project_id
  # See available locations: https://firebase.google.com/docs/projects/locations#default-cloud-location
  # This will set the location for the default Storage bucket and the App Engine App.
  location_id = "name-of-region"  # Must be in the same location as Firestore (above)

  # Wait for Firestore to be provisioned first.
  # Otherwise, the Firestore instance will be provisioned in Datastore mode (unusable by Firebase).
  depends_on = [
    google_firestore_database.firestore-fs,
  ]
}

# Makes the default Storage bucket accessible for Firebase SDKs, authentication, and Firebase Security Rules.
resource "google_firebase_storage_bucket" "default-bucket-fs" {
  provider  = google-beta
  project   = google_project.fs.project_id
  bucket_id = google_app_engine_application.default-bucket-fs.default_bucket
}

# Creates a ruleset of Cloud Storage Security Rules from a local file.
resource "google_firebaserules_ruleset" "default-bucket-fs" {
  provider = google-beta
  project  = google_project.fs.project_id
  source {
    files {
      # Write security rules in a local file named "storage.rules".
      # Learn more: https://firebase.google.com/docs/storage/security/get-started
      name    = "storage.rules"
      content = file("storage.rules")
    }
  }

  # Wait for the Cloud Storage bucket to be provisioned before creating this ruleset.
  depends_on = [
    google_firebase_project.fs,
  ]
}

# Releases the ruleset to the default Storage bucket.
resource "google_firebaserules_release" "default-bucket-fs" {
  provider     = google-beta
  name         = "firebase.storage/${google_app_engine_application.default-bucket-fs.default_bucket}"
  ruleset_name = "projects/${google_project.fs.project_id}/rulesets/${google_firebaserules_ruleset.default-bucket-fs.name}"
  project      = google_project.fs.project_id
}

এটি হল ক্লাউড ফায়ারস্টোর নিরাপত্তা বিধির নিয়ম যা firestore.rules নামে একটি স্থানীয় ফাইলে থাকা উচিত।

rules_version = '2';
service cloud.firestore {
  match /databases/{database}/documents {
    allow read: if request.auth != null;
    allow create: if request.auth != null;
    allow update: if request.auth != null;
  }
}

এটি হল ক্লাউড স্টোরেজ সিকিউরিটি রুলসের রুলসেট যা storage.rules নামে একটি স্থানীয় ফাইলে থাকা উচিত।

rules_version = '2';
service firebase.storage {
  match /b/{bucket}/o {
    match /{allPaths=**} {
      allow read, write: if request.auth != null;
    }
  }
}

Firebase অ্যাপ চেকের মাধ্যমে একটি API সংস্থান সুরক্ষিত করুন

এই কনফিগারেশনটি একটি নতুন Google ক্লাউড প্রকল্প তৈরি করে, প্রকল্পের জন্য Firebase পরিষেবাগুলিকে সক্ষম করে এবং ক্লাউড ফায়ারস্টোরের জন্য Firebase অ্যাপ চেকের প্রয়োগ সেট আপ এবং সক্ষম করে যাতে এটি শুধুমাত্র আপনার Android অ্যাপ থেকে অ্যাক্সেস করা যায়৷

# Creates a new Google Cloud project.
resource "google_project" "appcheck" {
  provider   = google-beta.no_user_project_override
  folder_id  = "folder-id-for-new-project"
  name       = "Project Display Name"
  project_id = "project-id-for-new-project"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "services" {
  provider = google-beta.no_user_project_override
  project  = google_project.appcheck.project_id
  for_each = toset([
    "cloudresourcemanager.googleapis.com",
    "firebase.googleapis.com",
    "firebaseappcheck.googleapis.com",
    "firestore.googleapis.com",
    "serviceusage.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created earlier.
resource "google_firebase_project" "appcheck" {
  provider = google-beta
  project  = google_project.appcheck.project_id

  depends_on = [google_project_service.services]
}

# Provisions the Firestore database instance.
resource "google_firestore_database" "database" {
  provider = google-beta
  project  = google_firebase_project.appcheck.project
  name     = "(default)"
  # See available locations: https://firebase.google.com/docs/projects/locations#default-cloud-location
  location_id = "name-of-region"
  # "FIRESTORE_NATIVE" is required to use Firestore with Firebase SDKs, authentication, and Firebase Security Rules.
  type             = "FIRESTORE_NATIVE"
  concurrency_mode = "OPTIMISTIC"

  # Wait for Firebase to be enabled in the Google Cloud project before initializing Firestore.
  depends_on = [
    google_firebase_project.appcheck,
  ]
}

# Creates a Firebase Android App in the new project created earlier.
resource "google_firebase_android_app" "appcheck" {
  provider     = google-beta
  project      = google_firebase_project.appcheck.project
  display_name = "Play Integrity app"
  package_name = "package.name.playintegrity"
  sha256_hashes = [
    # TODO: insert your Android app's SHA256 certificate
  ]
}

# It takes a while for App Check to recognize the new app
# If your app already exists, you don't have to wait 30 seconds.
resource "time_sleep" "wait_30s" {
  depends_on      = [google_firebase_android_app.appcheck]
  create_duration = "30s"
}

# Register the Android app with the Play Integrity provider
resource "google_firebase_app_check_play_integrity_config" "appcheck" {
  provider = google-beta
  project  = google_firebase_project.appcheck.project
  app_id   = google_firebase_android_app.appcheck.app_id

  depends_on = [time_sleep.wait_30s, google_firestore_database.database]

  lifecycle {
    precondition {
      condition     = length(google_firebase_android_app.appcheck.sha256_hashes) > 0
      error_message = "Provide a SHA-256 certificate on the Android App to use App Check"
    }
  }
}

# Enable enforcement of App Check for Firestore
resource "google_firebase_app_check_service_config" "firestore" {
  provider = google-beta

  project    = google_firebase_project.appcheck.project
  service_id = "firestore.googleapis.com"

  depends_on = [google_project_service.services]
}

একটি ফায়ারবেস এক্সটেনশনের একটি উদাহরণ ইনস্টল করুন

এই কনফিগারেশনটি একটি নতুন Google ক্লাউড প্রকল্প তৈরি করে, প্রকল্পের জন্য Firebase পরিষেবাগুলি সক্ষম করে এবং প্রকল্পে একটি Firebase এক্সটেনশনের একটি নতুন উদাহরণ ইনস্টল করে৷ দৃষ্টান্তটি ইতিমধ্যেই বিদ্যমান থাকলে, কনফিগারে প্রদত্ত মানগুলির উপর ভিত্তি করে এর পরামিতিগুলি আপডেট করা হয়।

# Creates a new Google Cloud project.
resource "google_project" "extensions" {
  provider   = google-beta.no_user_project_override
  folder_id  = "folder-id-for-new-project"
  name       = "Project Display Name"
  project_id = "project-id-for-new-project"

  # Associates the project with a Cloud Billing account
  # (required to use Firebase Extensions).
  billing_account = "000000-000000-000000"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "extensions" {
  provider = google-beta.no_user_project_override
  project  = google_project.extensions.project_id
  for_each = toset([
    "cloudbilling.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "serviceusage.googleapis.com",
    "firebase.googleapis.com",
    "firebaseextensions.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "extensions" {
  provider = google-beta
  project  = google_project.extensions.project_id

  depends_on = [
    google_project_service.extensions,
  ]
}

# Installs an instance of the "Translate Text in Firestore" extension.
# Or updates the extension if the specified instance already exists.
resource "google_firebase_extensions_instance" "translation" {
  provider = google-beta
  project = google_project.extensions.project_id

  instance_id = "translate-text-in-firestore"
  config {
    extension_ref = "firebase/firestore-translate-text"

    params = {
      COLLECTION_PATH      = "posts/comments/translations"
      DO_BACKFILL          = true
      LANGUAGES            = "ar,en,es,de,fr"
      INPUT_FIELD_NAME     = "input"
      LANGUAGES_FIELD_NAME = "languages"
      OUTPUT_FIELD_NAME    = "translated"
    }

    system_params = {
      "firebaseextensions.v1beta.function/location"                   = "us-central1"
      "firebaseextensions.v1beta.function/memory"                     = "256"
      "firebaseextensions.v1beta.function/minInstances"               = "0"
      "firebaseextensions.v1beta.function/vpcConnectorEgressSettings" = "VPC_CONNECTOR_EGRESS_SETTINGS_UNSPECIFIED"
    }
  }
}

আপনি সমস্ত বিভিন্ন প্রকল্প-সম্পর্কিত বৈশিষ্ট্য (যেমন project এবং user_project_override ) সম্পর্কে আরও জানতে চান

এই নির্দেশিকাটি "প্রকল্প" এর সাথে কাজ করার সময় নিম্নলিখিত Terraform বৈশিষ্ট্যগুলি ব্যবহার করে।

একটি resource ব্লকের মধ্যে project

প্রস্তাবিত: যখনই সম্ভব, প্রতিটি resource ব্লকের মধ্যে project বৈশিষ্ট্য অন্তর্ভুক্ত করুন

একটি প্রকল্প বৈশিষ্ট্য অন্তর্ভুক্ত করে, Terraform নির্দিষ্ট প্রকল্পের মধ্যে রিসোর্স ব্লকে নির্দিষ্ট পরিকাঠামো তৈরি করবে। এই গাইড এবং আমাদের নমুনা কনফিগার ফাইলগুলি এই অনুশীলনটি ব্যবহার করে।

project সম্পর্কে অফিসিয়াল Terraform ডকুমেন্টেশন দেখুন.

provider ব্লকের মধ্যে user_project_override

বেশিরভাগ সম্পদের ব্যবস্থা করার জন্য, আপনাকে user_project_override = true ব্যবহার করতে হবে, যার অর্থ আপনার নিজের ফায়ারবেস প্রকল্পের বিপরীতে কোটা পরীক্ষা করা। যাইহোক, আপনার নতুন প্রকল্প সেট আপ করতে যাতে এটি কোটা চেক গ্রহণ করতে পারে, আপনাকে প্রথমে user_project_override = false ব্যবহার করতে হবে।

user_project_override সম্পর্কে অফিসিয়াল Terraform ডকুমেন্টেশন দেখুন।

আপনি এই ত্রুটিটি পেয়েছেন: generic::permission_denied: Firebase Tos Not Accepted .

নিশ্চিত করুন যে আপনি যে ব্যবহারকারীর অ্যাকাউন্টটি gCloud CLI কমান্ডগুলি চালানোর জন্য ব্যবহার করছেন সেটি Firebase পরিষেবার শর্তাবলী (Firebase ToS) স্বীকার করেছে৷

• আপনি ব্যবহারকারীর অ্যাকাউন্টে সাইন ইন করা একটি ব্রাউজার ব্যবহার করে এবং Firebase কনসোলে একটি বিদ্যমান Firebase প্রকল্প দেখার চেষ্টা করে এই পরীক্ষাটি করতে পারেন। আপনি যদি একটি বিদ্যমান Firebase প্রকল্প দেখতে পারেন, তাহলে ব্যবহারকারীর অ্যাকাউন্ট Firebase ToS স্বীকার করেছে।

• আপনি যদি কোনো বিদ্যমান ফায়ারবেস প্রজেক্ট দেখতে না পান, তাহলে ব্যবহারকারীর অ্যাকাউন্ট সম্ভবত Firebase ToS স্বীকার করেনি। এটি ঠিক করতে, Firebase কনসোলের মাধ্যমে একটি নতুন Firebase প্রকল্প তৈরি করুন এবং প্রকল্প তৈরির অংশ হিসাবে Firebase ToS গ্রহণ করুন৷ আপনি কনসোলে প্রজেক্ট সেটিংসের মাধ্যমে অবিলম্বে এই প্রকল্পটি মুছে ফেলতে পারেন।

terraform apply করার পরে, আপনি এই ত্রুটিটি পাবেন: generic::permission_denied: IAM authority does not have the permission ।

কয়েক মিনিট অপেক্ষা করুন, এবং তারপর আবার terraform apply চেষ্টা করুন।

একটি সংস্থান তৈরি করা ব্যর্থ হয়েছে, কিন্তু আপনি যখন terraform apply , এটি ALREADY_EXISTS বলে।

এটি বিভিন্ন সিস্টেমে প্রচার বিলম্বের কারণে হতে পারে। terraform import চালানোর মাধ্যমে টেরাফর্ম স্টেটে সম্পদ আমদানি করে এই সমস্যাটি সমাধান করার চেষ্টা করুন। তারপর আবার terraform apply চালানোর চেষ্টা করুন।

আপনি শিখতে পারেন কিভাবে প্রতিটি সম্পদ আমদানি করতে হয় তার Terraform ডকুমেন্টেশনের "আমদানি" বিভাগে (উদাহরণস্বরূপ, ক্লাউড ফায়ারস্টোরের জন্য "আমদানি" ডকুমেন্টেশন )।

ক্লাউড ফায়ারস্টোরের সাথে কাজ করার সময়, আপনি এই ত্রুটিটি পান: Error creating Index: googleapi: Error 409;...Concurrent access -- try again

ত্রুটির পরামর্শ অনুসারে, Terraform একাধিক সূচকের ব্যবস্থা করার চেষ্টা করতে পারে এবং/অথবা একই সময়ে একটি নথি তৈরি করতে পারে এবং একটি সমবর্তী ত্রুটির মধ্যে পড়ে। terraform apply ।

আপনি এই ত্রুটিটি পেয়েছেন: "you may need to specify 'X-Goog-User-Project' HTTP header for quota and billing purposes"

এই ত্রুটির অর্থ হল যে কোন প্রকল্পের বিপরীতে কোটা পরীক্ষা করতে হবে তা Terraform জানে না। সমস্যা সমাধানের জন্য, resource ব্লকে নিম্নলিখিত চেক করুন:

• আপনি project অ্যাট্রিবিউটের জন্য একটি মান নির্দিষ্ট করেছেন তা নিশ্চিত করুন।
• নিশ্চিত করুন যে আপনি user_project_override = true (কোনও উপনাম নেই) সহ প্রদানকারী ব্যবহার করছেন, যেটি Firebase নমুনাগুলিতে google-beta ।

একটি নতুন Google ক্লাউড প্রকল্প তৈরি করার সময়, আপনি ত্রুটিটি পান যে নতুন প্রকল্পের জন্য নির্দিষ্ট করা প্রকল্প আইডি ইতিমধ্যেই বিদ্যমান।

প্রকল্প আইডি ইতিমধ্যেই বিদ্যমান থাকতে পারে এমন সম্ভাব্য কারণগুলি এখানে রয়েছে:

• সেই আইডির সাথে যুক্ত প্রকল্পটি অন্য কারো।

  • সমাধান করতে: অন্য প্রকল্প আইডি চয়ন করুন।

• সেই আইডির সাথে যুক্ত প্রকল্পটি সম্প্রতি মুছে ফেলা হয়েছে (সফট-ডিলিট অবস্থায়)।

  • সমাধান করতে: আপনি যদি মনে করেন যে আইডির সাথে যুক্ত প্রকল্পটি আপনারই, তাহলে projects.get REST API ব্যবহার করে প্রকল্পের অবস্থা পরীক্ষা করুন।

• সেই আইডির সাথে যুক্ত প্রকল্পটি বর্তমান ব্যবহারকারীর অধীনে সঠিকভাবে বিদ্যমান। ত্রুটির একটি সম্ভাব্য কারণ হতে পারে যে একটি পূর্ববর্তী terraform apply বাধাগ্রস্ত হয়েছে।

  • সমাধান করতে: নিম্নলিখিত কমান্ডগুলি চালান:
    terraform import google_project.default PROJECT_ID এবং তারপর
    terraform import google_firebase_project.default PROJECT_ID

ক্লাউড ফায়ারস্টোর এবং তারপরে ক্লাউড স্টোরেজ ( google_app_engine_application এর মাধ্যমে) বিধান করার চেষ্টা করার সময়, আপনি এই ত্রুটিটি পান: Error: Error creating App Engine application: googleapi: Error 409: Cannot create Firestore database resource <resource-name> since it already exists at location <location-id>, alreadyExists ।

একটি অ্যাপ ইঞ্জিন অ্যাপ্লিকেশনের জন্য একটি ক্লাউড ফায়ারস্টোর দৃষ্টান্ত প্রয়োজন, তবে আপনি প্রতি প্রকল্পে শুধুমাত্র একটি ক্লাউড ফায়ারস্টোর দৃষ্টান্ত রাখতে পারেন। সুতরাং, ত্রুটির বার্তাটি প্রস্তাব করে, আপনি যদি ইতিমধ্যেই একটি স্থানে প্রকল্পের ক্লাউড ফায়ারস্টোর দৃষ্টান্তের ব্যবস্থা করে থাকেন, আপনি যদি অন্য স্থানে একটি ক্লাউড ফায়ারস্টোর দৃষ্টান্ত সরবরাহ করার চেষ্টা করেন তবে অ্যাপ ইঞ্জিন ত্রুটি করবে৷ অ্যাপ ইঞ্জিন মনে করে যে আপনি ইতিমধ্যে বিদ্যমান ক্লাউড ফায়ারস্টোর উদাহরণটিকে "পুনরায় বিধান" করার চেষ্টা করছেন৷

এই ত্রুটিটি সমাধান করতে, ক্লাউড ফায়ারস্টোর এবং অ্যাপ ইঞ্জিন অ্যাপ্লিকেশন উভয়ের জন্য একই অবস্থান ব্যবহার করুন৷ আপনার যদি ক্লাউড ফায়ারস্টোর থেকে আলাদা জায়গায় একটি ক্লাউড স্টোরেজ বাকেটের প্রয়োজন হয়, আপনি অতিরিক্ত বালতি সরবরাহ করতে পারেন ( একাধিক ক্লাউড স্টোরেজ বালতি তৈরির জন্য নমুনা কনফিগারেশন দেখুন)।

ক্লাউড স্টোরেজ ( google_app_engine_application এর মাধ্যমে) এবং তারপরে ক্লাউড ফায়ারস্টোরের ব্যবস্থা করার চেষ্টা করার সময়, আপনি এই ত্রুটিটি পান: Error: Error creating Database: googleapi: Error 409: Database already exists. Please use another database_id ।

আপনি যখন একটি প্রজেক্টের ডিফল্ট ক্লাউড স্টোরেজ বাকেট ( google_app_engine_application এর মাধ্যমে) প্রভিশন করেন এবং প্রোজেক্টে এখনও ক্লাউড ফায়ারস্টোর ইনস্ট্যান্স থাকে না, তখন google_app_engine_application স্বয়ংক্রিয়ভাবে প্রোজেক্টের ক্লাউড ফায়ারস্টোর ইনস্ট্যান্সের ব্যবস্থা করে।

সুতরাং, যদি আপনার প্রজেক্টের ক্লাউড ফায়ারস্টোর দৃষ্টান্ত ইতিমধ্যেই প্রভিশন করা থাকে, তাহলে google_firestore_database ত্রুটি করবে যদি আপনি ক্লাউড ফায়ারস্টোর দৃষ্টান্তের সুস্পষ্টভাবে ব্যবস্থা করার চেষ্টা করেন।

একবার প্রজেক্টের ক্লাউড ফায়ারস্টোর দৃষ্টান্তের ব্যবস্থা করা হলে, আপনি এটিকে "পুনরায় বিধান" করতে বা এর অবস্থান পরিবর্তন করতে পারবেন না। ত্রুটিটি ঘটতে বাধা দিতে, আপনার কনফিগার ফাইল থেকে google_firestore_database রিসোর্স ব্লকটি সরান। মনে রাখবেন, যদিও, আমরা প্রজেক্টের ডিফল্ট ক্লাউড স্টোরেজ বাকেটের আগে ক্লাউড ফায়ারস্টোরের ব্যবস্থা করার পরামর্শ দিই (কেনের জন্য নীচের অংশটি দেখুন)।