टेराफॉर्म और फायरबेस के साथ शुरुआत करें

इस उदाहरण कॉन्फ़िग फ़ाइल का एक उच्च एनोटेटेड संस्करण देखें

यदि आप संसाधनों के रूप में परियोजनाओं और ऐप्स के बुनियादी ढांचे से परिचित नहीं हैं, तो निम्नलिखित दस्तावेज़ की समीक्षा करें:

• फायरबेस परियोजनाओं को समझें
• फायरबेस परियोजना प्रबंधन के लिए संदर्भ दस्तावेज़

# Terraform configuration to set up providers by version.
...

# Configures the provider to use the resource block's specified project for quota checks.
...

# Configures the provider to not use the resource block's specified project for quota checks.
...

# Creates a new Google Cloud project.
resource "google_project" "default" {
  # Use the provider that enables the setup of quota checks for a new project
  provider   = google-beta.no_user_project_override

  name            = "Project Display Name"        // learn more about the project name
  project_id      = "project-id-for-new-project"  // learn more about the project ID
  # Required for any service that requires the Blaze pricing plan
  # (like Firebase Authentication with GCIP)
  billing_account = "000000-000000-000000"

  # Required for the project to display in any list of Firebase projects.
  labels = {
    "firebase" = "enabled"  // learn more about the Firebase-enabled label
  }
}

# Enables required APIs.
resource "google_project_service" "default" {
  # Use the provider without quota checks for enabling APIS
  provider = google-beta.no_user_project_override
  project  = google_project.default.project_id
  for_each = toset([
    "cloudbilling.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "firebase.googleapis.com",
    # Enabling the ServiceUsage API allows the new project to be quota checked from now on.
    "serviceusage.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
# This action essentially "creates a Firebase project" and allows the project to use
# Firebase services (like Firebase Authentication) and
# Firebase tooling (like the Firebase console).
# Learn more about the relationship between Firebase projects and Google Cloud.
resource "google_firebase_project" "default" {
  # Use the provider that performs quota checks from now on
  provider = google-beta

  project  = google_project.default.project_id

  # Waits for the required APIs to be enabled.
  depends_on = [
    google_project_service.default
  ]
}

# Creates a Firebase Android App in the new project created above.
# Learn more about the relationship between Firebase Apps and Firebase projects.
resource "google_firebase_android_app" "default" {
  provider = google-beta

  project      = google_project.default.project_id
  display_name = "My Awesome Android app"  # learn more about an app's display name
  package_name = "awesome.package.name"    # learn more about an app's package name

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.default,
  ]
}

जीसीआईपी के साथ फायरबेस प्रमाणीकरण सेट करें

यह कॉन्फ़िगरेशन एक नया Google क्लाउड प्रोजेक्ट बनाता है, प्रोजेक्ट को क्लाउड बिलिंग खाते से जोड़ता है (जीसीआईपी के साथ फायरबेस प्रमाणीकरण के लिए ब्लेज़ मूल्य निर्धारण योजना आवश्यक है), प्रोजेक्ट के लिए फायरबेस सेवाओं को सक्षम करता है, जीसीआईपी के साथ फायरबेस प्रमाणीकरण सेट करता है, और तीन अलग-अलग ऐप पंजीकृत करता है प्रोजेक्ट के साथ प्रकार।

ध्यान दें कि टेराफॉर्म के माध्यम से फायरबेस प्रमाणीकरण स्थापित करने के लिए जीसीआईपी को सक्षम करना आवश्यक है।

# Creates a new Google Cloud project.
resource "google_project" "auth" {
  provider  = google-beta.no_user_project_override
  folder_id = "folder-id-for-new-project"
  name            = "Project Display Name"
  project_id      = "project-id-for-new-project"

  # Associates the project with a Cloud Billing account
  # (required for Firebase Authentication with GCIP).
  billing_account = "000000-000000-000000"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "auth" {
  provider = google-beta.no_user_project_override
  project  = google_project.auth.project_id
  for_each = toset([
    "cloudbilling.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "serviceusage.googleapis.com",
    "identitytoolkit.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "auth" {
  provider = google-beta
  project  = google_project.auth.project_id

  depends_on = [
    google_project_service.auth,
  ]
}

# Creates an Identity Platform config.
# Also enables Firebase Authentication with Identity Platform in the project if not.
resource "google_identity_platform_config" "auth" {
  provider = google-beta
  project  = google_project.auth.project_id

  # Auto-deletes anonymous users
  autodelete_anonymous_users = true

  # Configures local sign-in methods, like anonymous, email/password, and phone authentication.
  sign_in {
    allow_duplicate_emails = true

    anonymous {
      enabled = true
    }

    email {
      enabled = true
      password_required = false
    }

    phone_number {
      enabled = true
      test_phone_numbers = {
        "+11231231234" = "000000"
      }
    }
  }

  # Sets an SMS region policy.
  sms_region_config {
    allowlist_only {
      allowed_regions = [
        "US",
        "CA",
      ]
    }
  }

  # Configures blocking functions.
  blocking_functions {
    triggers {
      event_type = "beforeSignIn"
      function_uri = "https://us-east1-${google_project.auth.project_id}.cloudfunctions.net/before-sign-in"
    }
    forward_inbound_credentials {
      refresh_token = true
      access_token = true
      id_token = true
    }
  }

  # Configures a temporary quota for new signups for anonymous, email/password, and phone number.
  quota {
    sign_up_quota_config {
      quota = 1000
      start_time = ""
      quota_duration = "7200s"
    }
  }

  # Configures authorized domains.
  authorized_domains = [
    "localhost",
    "${google_project.auth.project_id}.firebaseapp.com",
    "${google_project.auth.project_id}.web.app",
  ]

  # Wait for identitytoolkit.googleapis.com to be enabled before initializing Authentication.
  depends_on = [
    google_project_service.auth,
  ]
}

# Creates a Firebase Android App in the new project created above.
resource "google_firebase_android_app" "auth" {
  provider     = google-beta
  project      = google_project.auth.project_id
  display_name = "My Android app"
  package_name = "android.package.name"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.auth,
  ]
}

# Creates a Firebase Apple-platforms App in the new project created above.
resource "google_firebase_apple_app" "auth" {
  provider     = google-beta
  project      = google_project.auth.project_id
  display_name = "My Apple app"
  bundle_id    = "apple.app.12345"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.auth,
  ]
}

# Creates a Firebase Web App in the new project created above.
resource "google_firebase_web_app" "auth" {
  provider     = google-beta
  project      = google_project.auth.project_id
  display_name = "My Web app"

  # The other App types (Android and Apple) use "DELETE" by default.
  # Web apps don't use "DELETE" by default due to backward-compatibility.
  deletion_policy = "DELETE"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.auth,
  ]
}

डिफ़ॉल्ट फ़ायरबेस रीयलटाइम डेटाबेस उदाहरण का प्रावधान करें

यह कॉन्फ़िगरेशन एक नया Google क्लाउड प्रोजेक्ट बनाता है, प्रोजेक्ट के लिए फायरबेस सेवाओं को सक्षम करता है, प्रोजेक्ट के डिफ़ॉल्ट रीयलटाइम डेटाबेस इंस्टेंस का प्रावधान करता है, और प्रोजेक्ट के साथ तीन अलग-अलग ऐप प्रकारों को पंजीकृत करता है।

# Creates a new Google Cloud project.
resource "google_project" "rtdb" {
  provider   = google-beta.no_user_project_override
  folder_id  = "folder-id-for-new-project"
  name       = "Project Display Name"
  project_id = "project-id-for-new-project"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "rtdb" {
  provider = google-beta.no_user_project_override
  project  = google_project.rtdb.project_id
  for_each = toset([
    "serviceusage.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "firebasedatabase.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "rtdb" {
  provider = google-beta
  project  = google_project.rtdb.project_id
}

# Provisions the default Realtime Database default instance.
resource "google_firebase_database_instance" "database" {
  provider    = google-beta
  project     = google_project.rtdb.project_id
  # See available locations: https://firebase.google.com/docs/projects/locations#rtdb-locations
  region      = "name-of-region"
  # This value will become the first segment of the database's URL.
  instance_id = "${google_project.rtdb.project_id}-default-rtdb"
  type        = "DEFAULT_DATABASE"

  # Wait for Firebase to be enabled in the Google Cloud project before initializing Realtime Database.
  depends_on = [
    google_firebase_project.rtdb,
  ]
}

# Creates a Firebase Android App in the new project created above.
resource "google_firebase_android_app" "rtdb" {
  provider     = google-beta
  project      = google_project.rtdb.project_id
  display_name = "My Android app"
  package_name = "android.package.name"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.rtdb,
  ]
}

# Creates a Firebase Apple-platforms App in the new project created above.
resource "google_firebase_apple_app" "rtdb" {
  provider     = google-beta
  project      = google_project.rtdb.project_id
  display_name = "My Apple app"
  bundle_id    = "apple.app.12345"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.rtdb,
  ]
}

# Creates a Firebase Web App in the new project created above.
resource "google_firebase_web_app" "rtdb" {
  provider     = google-beta
  project      = google_project.rtdb.project_id
  display_name = "My Web app"

  # The other App types (Android and Apple) use "DELETE" by default.
  # Web apps don't use "DELETE" by default due to backward-compatibility.
  deletion_policy = "DELETE"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.rtdb,
  ]
}

एकाधिक फ़ायरबेस रीयलटाइम डेटाबेस उदाहरणों का प्रावधान करें

यह कॉन्फ़िगरेशन एक नया Google क्लाउड प्रोजेक्ट बनाता है, प्रोजेक्ट को क्लाउड बिलिंग खाते से जोड़ता है (कई रीयलटाइम डेटाबेस इंस्टेंसेस के लिए ब्लेज़ मूल्य निर्धारण योजना आवश्यक है), प्रोजेक्ट के लिए फायरबेस सेवाओं को सक्षम करता है, कई रीयलटाइम डेटाबेस इंस्टेंसेस का प्रावधान करता है (प्रोजेक्ट के डिफ़ॉल्ट रीयलटाइम डेटाबेस सहित) उदाहरण), और प्रोजेक्ट के साथ तीन अलग-अलग ऐप प्रकार पंजीकृत करता है।

# Creates a new Google Cloud project.
resource "google_project" "rtdb-multi" {
  provider   = google-beta.no_user_project_override
  folder_id  = "folder-id-for-new-project"
  name       = "Project Display Name"
  project_id = "project-id-for-new-project"

  # Associate the project with a Cloud Billing account
  # (required for multiple Realtime Database instances).
  billing_account = "000000-000000-000000"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "rtdb-multi" {
  provider = google-beta.no_user_project_override
  project  = google_project.rtdb-multi.project_id
  for_each = toset([
    "cloudbilling.googleapis.com",
    "serviceusage.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "firebasedatabase.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "rtdb-multi" {
  provider = google-beta
  project  = google_project.rtdb-multi.project_id
}

# Provisions the default Realtime Database default instance.
resource "google_firebase_database_instance" "database-default" {
  provider    = google-beta
  project     = google_project.rtdb-multi.project_id
  # See available locations: https://firebase.google.com/docs/projects/locations#rtdb-locations
  region      = "name-of-region"
  # This value will become the first segment of the database's URL.
  instance_id = "${google_project.rtdb-multi.project_id}-default-rtdb"
  type        = "DEFAULT_DATABASE"

  # Wait for Firebase to be enabled in the Google Cloud project before initializing Realtime Database.
  depends_on = [
    google_firebase_project.rtdb-multi,
  ]
}

# Provisions an additional Realtime Database instance.
resource "google_firebase_database_instance" "database-additional" {
  provider    = google-beta
  project     = google_project.rtdb-multi.project_id
  # See available locations: https://firebase.google.com/docs/projects/locations#rtdb-locations
  # This location doesn't need to be the same as the default database instance.
  region      = "name-of-region"
  # This value will become the first segment of the database's URL.
  instance_id = "name-of-additional-database-instance"
  type        = "USER_DATABASE"

  # Wait for Firebase to be enabled in the Google Cloud project before initializing Realtime Database.
  depends_on = [
    google_firebase_project.rtdb-multi,
  ]
}

# Creates a Firebase Android App in the new project created above.
resource "google_firebase_android_app" "rtdb-multi" {
  provider     = google-beta
  project      = google_project.rtdb-multi.project_id
  display_name = "My Android app"
  package_name = "android.package.name"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.rtdb-multi,
  ]
}

# Creates a Firebase Apple-platforms App in the new project created above.
resource "google_firebase_apple_app" "rtdb-multi" {
  provider     = google-beta
  project      = google_project.rtdb-multi.project_id
  display_name = "My Apple app"
  bundle_id    = "apple.app.12345"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.rtdb-multi,
  ]
}

# Creates a Firebase Web App in the new project created above.
resource "google_firebase_web_app" "rtdb-multi" {
  provider     = google-beta
  project      = google_project.rtdb-multi.project_id
  display_name = "My Web app"

  # The other App types (Android and Apple) use "DELETE" by default.
  # Web apps don't use "DELETE" by default due to backward-compatibility.
  deletion_policy = "DELETE"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.rtdb-multi,
  ]
}

क्लाउड फायरस्टोर उदाहरण का प्रावधान करें

यह कॉन्फ़िगरेशन एक नया Google क्लाउड प्रोजेक्ट बनाता है, प्रोजेक्ट के लिए फायरबेस सेवाओं को सक्षम करता है, प्रोजेक्ट के क्लाउड फायरस्टोर इंस्टेंस का प्रावधान करता है, और प्रोजेक्ट के साथ तीन अलग-अलग ऐप प्रकारों को पंजीकृत करता है।

यह क्लाउड फायरस्टोर उदाहरण के लिए फायरबेस सुरक्षा नियमों का भी प्रावधान करता है, क्लाउड फायरस्टोर इंडेक्स बनाता है, और बीज डेटा के साथ क्लाउड फायरस्टोर दस्तावेज़ जोड़ता है।

# Creates a new Google Cloud project.
resource "google_project" "firestore" {
  provider   = google-beta.no_user_project_override
  folder_id  = "folder-id-for-new-project"
  name       = "Project Display Name"
  project_id = "project-id-for-new-project"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "firestore" {
  provider = google-beta.no_user_project_override
  project  = google_project.firestore.project_id
  for_each = toset([
    "cloudresourcemanager.googleapis.com",
    "serviceusage.googleapis.com",
    "firestore.googleapis.com",
    "firebaserules.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "firestore" {
  provider = google-beta
  project  = google_project.firestore.project_id
}

# Provisions the Firestore database instance.
resource "google_firestore_database" "firestore" {
  provider                    = google-beta
  project                     = google_project.firestore.project_id
  name                        = "(default)"
  # See available locations: https://firebase.google.com/docs/projects/locations#default-cloud-location
  location_id                 = "name-of-region"
  # "FIRESTORE_NATIVE" is required to use Firestore with Firebase SDKs, authentication, and Firebase Security Rules.
  type                        = "FIRESTORE_NATIVE"
  concurrency_mode            = "OPTIMISTIC"

  # Wait for Firebase to be enabled in the Google Cloud project before initializing Firestore.
  depends_on = [
    google_firebase_project.firestore,
  ]
}

# Creates a ruleset of Firestore Security Rules from a local file.
resource "google_firebaserules_ruleset" "firestore" {
  provider = google-beta
  project  = google_project.firestore.project_id
  source {
    files {
      name = "firestore.rules"
      # Write security rules in a local file named "firestore.rules".
      # Learn more: https://firebase.google.com/docs/firestore/security/get-started
      content = file("firestore.rules")
    }
  }

  # Wait for Firestore to be provisioned before creating this ruleset.
  depends_on = [
    google_firestore_database.firestore,
  ]
}

# Releases the ruleset for the Firestore instance.
resource "google_firebaserules_release" "firestore" {
  provider     = google-beta
  name         = "cloud.firestore"  # must be cloud.firestore
  ruleset_name = google_firebaserules_ruleset.firestore.name
  project      = google_project.firestore.project_id

  # Wait for Firestore to be provisioned before releasing the ruleset.
  depends_on = [
    google_firestore_database.firestore,
  ]
}

# Adds a new Firestore index.
resource "google_firestore_index" "indexes" {
  provider = google-beta
  project  = google_project.firestore.project_id

  collection  = "quiz"
  query_scope = "COLLECTION"

  fields {
    field_path = "question"
    order      = "ASCENDING"
  }

  fields {
    field_path = "answer"
    order      = "ASCENDING"
  }

  # Wait for Firestore to be provisioned before adding this index.
  depends_on = [
    google_firestore_database.firestore,
  ]
}

# Adds a new Firestore document with seed data.
# Don't use real end-user or production data in this seed document.
resource "google_firestore_document" "doc" {
  provider    = google-beta
  project     = google_project.firestore.project_id
  collection  = "quiz"
  document_id = "question-1"
  fields      = "{\"question\":{\"stringValue\":\"Favorite Database\"},\"answer\":{\"stringValue\":\"Firestore\"}}"

  # Wait for Firestore to be provisioned before adding this document.
  depends_on = [
    google_firestore_database.firestore,
  ]
}

# Creates a Firebase Android App in the new project created above.
resource "google_firebase_android_app" "firestore" {
  provider     = google-beta
  project      = google_project.firestore.project_id
  display_name = "My Android app"
  package_name = "android.package.name"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.firestore,
  ]
}

# Creates a Firebase Apple-platforms App in the new project created above.
resource "google_firebase_apple_app" "firestore" {
  provider     = google-beta
  project      = google_project.firestore.project_id
  display_name = "My Apple app"
  bundle_id    = "apple.app.12345"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.firestore,
  ]
}

# Creates a Firebase Web App in the new project created above.
resource "google_firebase_web_app" "firestore" {
  provider     = google-beta
  project      = google_project.firestore.project_id
  display_name = "My Web app"

  # The other App types (Android and Apple) use "DELETE" by default.
  # Web apps don't use "DELETE" by default due to backward-compatibility.
  deletion_policy = "DELETE"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.firestore,
  ]
}

यह क्लाउड फायरस्टोर सुरक्षा नियमों का नियम है जो firestore.rules नामक स्थानीय फ़ाइल में होना चाहिए।

rules_version = '2';
service cloud.firestore {
  match /databases/{database}/documents {
    allow read: if request.auth != null;
    allow create: if request.auth != null;
    allow update: if request.auth != null;
  }
}

डिफ़ॉल्ट क्लाउड स्टोरेज बकेट का प्रावधान करें

यह कॉन्फ़िगरेशन एक नया Google क्लाउड प्रोजेक्ट बनाता है, प्रोजेक्ट के लिए फायरबेस सेवाओं को सक्षम करता है, प्रोजेक्ट के डिफ़ॉल्ट क्लाउड स्टोरेज बकेट का प्रावधान करता है, और प्रोजेक्ट के साथ तीन अलग-अलग ऐप प्रकारों को पंजीकृत करता है।

यह क्लाउड स्टोरेज बकेट के लिए फायरबेस सुरक्षा नियमों का भी प्रावधान करता है, और बकेट में एक फ़ाइल अपलोड करता है।

# Creates a new Google Cloud project.
resource "google_project" "storage" {
  provider   = google-beta.no_user_project_override
  folder_id  = "folder-id-for-new-project"
  name       = "Project Display Name"
  project_id = "project-id-for-new-project"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "storage" {
  provider = google-beta.no_user_project_override
  project  = google_project.storage.project_id
  for_each = toset([
    "serviceusage.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "firebaserules.googleapis.com",
    "firebasestorage.googleapis.com",
    "storage.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "storage" {
  provider = google-beta
  project  = google_project.storage.project_id
}

# Provisions the default Cloud Storage bucket for the project via Google App Engine.
resource "google_app_engine_application" "default" {
  provider    = google-beta
  project     = google_project.storage.project_id
  # See available locations: https://firebase.google.com/docs/projects/locations#default-cloud-location
  # This will set the location for the default Storage bucket and the App Engine App.
  location_id = "name-of-region-for-default-bucket"

  # If you use Firestore, uncomment this to make sure Firestore is provisioned first.
  # depends_on = [
    # google_firestore_database.firestore
  # ]
}

# Makes the default Storage bucket accessible for Firebase SDKs, authentication, and Firebase Security Rules.
resource "google_firebase_storage_bucket" "default-bucket" {
  provider  = google-beta
  project   = google_project.storage.project_id
  bucket_id = google_app_engine_application.default.default_bucket
}

# Creates a ruleset of Cloud Storage Security Rules from a local file.
resource "google_firebaserules_ruleset" "storage" {
  provider = google-beta
  project  = google_project.storage.project_id
  source {
    files {
      # Write security rules in a local file named "storage.rules".
      # Learn more: https://firebase.google.com/docs/storage/security/get-started
      name    = "storage.rules"
      content = file("storage.rules")
    }
  }

  # Wait for the default Storage bucket to be provisioned before creating this ruleset.
  depends_on = [
    google_firebase_project.storage,
  ]
}

# Releases the ruleset to the default Storage bucket.
resource "google_firebaserules_release" "default-bucket" {
  provider     = google-beta
  name         = "firebase.storage/${google_app_engine_application.default.default_bucket}"
  ruleset_name = "projects/${google_project.storage.project_id}/rulesets/${google_firebaserules_ruleset.storage.name}"
  project      = google_project.storage.project_id
}

# Uploads a new file to the default Storage bucket.
# Don't use real end-user or production data in this file.
resource "google_storage_bucket_object" "cat-picture" {
  provider = google-beta
  name     = "cat.png"
  source   = "path/to/cat.png"
  bucket   = google_app_engine_application.default.default_bucket
}

# Creates a Firebase Android App in the new project created above.
resource "google_firebase_android_app" "storage" {
  provider     = google-beta
  project      = google_project.storage.project_id
  display_name = "My Android app"
  package_name = "android.package.name"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.storage,
  ]
}

# Creates a Firebase Apple-platforms App in the new project created above.
resource "google_firebase_apple_app" "storage" {
  provider     = google-beta
  project      = google_project.storage.project_id
  display_name = "My Apple app"
  bundle_id    = "apple.app.12345"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.storage,
  ]
}

# Creates a Firebase Web App in the new project created above.
resource "google_firebase_web_app" "storage" {
  provider     = google-beta
  project      = google_project.storage.project_id
  display_name = "My Web app"

  # The other App types (Android and Apple) use "DELETE" by default.
  # Web apps don't use "DELETE" by default due to backward-compatibility.
  deletion_policy = "DELETE"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.storage,
  ]
}

यह क्लाउड स्टोरेज सुरक्षा नियमों का नियम है जो storage.rules नामक स्थानीय फ़ाइल में होना चाहिए।

rules_version = '2';
service firebase.storage {
  match /b/{bucket}/o {
    match /{allPaths=**} {
      allow read, write: if request.auth != null;
    }
  }
}

एकाधिक क्लाउड स्टोरेज बकेट का प्रावधान करें

यह कॉन्फ़िगरेशन एक नया Google क्लाउड प्रोजेक्ट बनाता है, प्रोजेक्ट को क्लाउड बिलिंग खाते से जोड़ता है (ब्लेज़ मूल्य निर्धारण योजना कई बकेट के लिए आवश्यक है), प्रोजेक्ट के लिए फायरबेस सेवाओं को सक्षम करता है, कई क्लाउड स्टोरेज बकेट का प्रावधान करता है (प्रोजेक्ट के डिफ़ॉल्ट क्लाउड स्टोरेज बकेट सहित) , और प्रोजेक्ट के साथ तीन अलग-अलग ऐप प्रकारों को पंजीकृत करता है।

यह क्लाउड स्टोरेज बकेट के लिए फायरबेस सुरक्षा नियमों का भी प्रावधान करता है, और एक फ़ाइल को डिफ़ॉल्ट क्लाउड स्टोरेज बकेट में अपलोड करता है।

# Creates a new Google Cloud project.
resource "google_project" "storage-multi" {
  provider  = google-beta.no_user_project_override
  folder_id = "folder-id-for-new-project"
  name            = "Project Display Name"
  project_id      = "project-id-for-new-project"

  # Associates the project with a Cloud Billing account
  # (required for multiple Cloud Storage buckets).
  billing_account = "000000-000000-000000"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "storage-multi" {
  provider = google-beta.no_user_project_override
  project  = google_project.storage-multi.project_id
  for_each = toset([
    "cloudbilling.googleapis.com",
    "serviceusage.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "firebaserules.googleapis.com",
    "firebasestorage.googleapis.com",
    "storage.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "storage-multi" {
  provider = google-beta
  project  = google_project.storage-multi.project_id
}

# Provisions the default Cloud Storage bucket for the project via Google App Engine.
resource "google_app_engine_application" "default-multi" {
  provider = google-beta
  project  = google_project.storage-multi.project_id
  # See available locations: https://firebase.google.com/docs/projects/locations#default-cloud-location
  # This will set the location for the default Storage bucket and the App Engine App.
  location_id = "name-of-region-for-default-bucket"

  # If you use Firestore, uncomment this to make sure Firestore is provisioned first.
  # depends_on = [
  # google_firestore_database.firestore
  # ]
}

# Provisions an additional Cloud Storage bucket.
# Additional Cloud Storage buckets are not provisioned via App Engine.
resource "google_storage_bucket" "bucket-multi" {
  provider = google-beta
  project  = google_project.storage-multi.project_id
  name     = "name-of-additional-storage-bucket"
  # See available locations: https://cloud.google.com/storage/docs/locations#available-locations
  # This location does not need to be the same as the default Storage bucket.
  location = "name-of-region-for-additional-bucket"
}

# Makes the default Storage bucket accessible for Firebase SDKs, authentication, and Firebase Security Rules.
resource "google_firebase_storage_bucket" "default-bucket-multi" {
  provider  = google-beta
  project   = google_project.storage-multi.project_id
  bucket_id = google_app_engine_application.default-multi.default_bucket
}

# Makes the additional Storage bucket accessible for Firebase SDKs, authentication, and Firebase Security Rules.
resource "google_firebase_storage_bucket" "bucket-multi" {
  provider  = google-beta
  project   = google_project.storage-multi.project_id
  bucket_id = google_storage_bucket.bucket-multi.name
}

# Creates a ruleset of Firebase Security Rules from a local file.
resource "google_firebaserules_ruleset" "storage-multi" {
  provider = google-beta
  project  = google_project.storage-multi.project_id
  source {
    files {
      # Write security rules in a local file named "storage.rules"
      # Learn more: https://firebase.google.com/docs/storage/security/get-started
      name    = "storage.rules"
      content = file("storage.rules")
    }
  }

  # Wait for the Storage buckets to be provisioned before creating this ruleset.
  depends_on = [
    google_firebase_project.storage-multi,
  ]
}

# Releases the ruleset to the default Storage bucket.
resource "google_firebaserules_release" "default-bucket-multi" {
  provider     = google-beta
  name         = "firebase.storage/${google_app_engine_application.default-multi.default_bucket}"
  ruleset_name = "projects/${google_project.storage-multi.project_id}/rulesets/${google_firebaserules_ruleset.storage-multi.name}"
  project      = google_project.storage-multi.project_id
}

# Releases the ruleset to the additional Storage bucket.
resource "google_firebaserules_release" "bucket-multi" {
  provider     = google-beta
  name         = "firebase.storage/${google_storage_bucket.bucket-multi.name}"
  ruleset_name = "projects/${google_project.storage-multi.project_id}/rulesets/${google_firebaserules_ruleset.storage-multi.name}"
  project      = google_project.storage-multi.project_id
}

# Uploads a new file to the default Storage bucket.
# Do not use real end-user or production data in this file.
resource "google_storage_bucket_object" "cat-picture-multi" {
  provider = google-beta
  name     = "cat.png"
  source   = "path/to/cat.png"
  bucket   = google_app_engine_application.default-multi.default_bucket
}

# Creates a Firebase Android App in the new project created above.
resource "google_firebase_android_app" "storage-multi" {
  provider     = google-beta
  project      = google_project.storage-multi.project_id
  display_name = "My Android app"
  package_name = "android.package.name"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.storage-multi,
  ]
}

# Creates a Firebase Apple-platforms App in the new project created above.
resource "google_firebase_apple_app" "storage-multi" {
  provider     = google-beta
  project      = google_project.storage-multi.project_id
  display_name = "My Apple app"
  bundle_id    = "apple.app.12345"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.storage-multi,
  ]
}

# Creates a Firebase Web App in the new project created above.
resource "google_firebase_web_app" "storage-multi" {
  provider     = google-beta
  project      = google_project.storage-multi.project_id
  display_name = "My Web app"

  # The other App types (Android and Apple) use "DELETE" by default.
  # Web apps don't use "DELETE" by default due to backward-compatibility.
  deletion_policy = "DELETE"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.storage-multi,
  ]
}

यह क्लाउड स्टोरेज सुरक्षा नियमों का नियम है जो storage.rules नामक स्थानीय फ़ाइल में होना चाहिए।

rules_version = '2';
service firebase.storage {
  match /b/{bucket}/o {
    match /{allPaths=**} {
      allow read, write: if request.auth != null;
    }
  }
}

क्लाउड फायरस्टोर इंस्टेंस और डिफ़ॉल्ट क्लाउड स्टोरेज बकेट का प्रावधान करें

यह कॉन्फ़िगरेशन एक नया Google क्लाउड प्रोजेक्ट बनाता है, प्रोजेक्ट के लिए फायरबेस सेवाओं को सक्षम करता है, क्लाउड फायरस्टोर इंस्टेंस का प्रावधान करता है, और फिर डिफ़ॉल्ट क्लाउड स्टोरेज बकेट का प्रावधान करता है।

यह क्लाउड फायरस्टोर इंस्टेंस और डिफ़ॉल्ट क्लाउड स्टोरेज बकेट के लिए फायरबेस सुरक्षा नियमों का भी प्रावधान करता है।

# Creates a new Google Cloud project.
resource "google_project" "fs" {  # fs = Firestore + Storage
  provider   = google-beta.no_user_project_override
  folder_id  = "folder-id-for-new-project"
  name       = "Project Display Name"
  project_id = "project-id-for-new-project"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "fs" {
  provider = google-beta.no_user_project_override
  project  = google_project.fs.project_id
  for_each = toset([
    "serviceusage.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "firebaserules.googleapis.com",
    "firebasestorage.googleapis.com",
    "storage.googleapis.com",
    "firestore.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "fs" {
  provider = google-beta
  project  = google_project.fs.project_id

}

#### Set up Firestore before default Cloud Storage bucket ####

# Provisions the Firestore database instance.
resource "google_firestore_database" "firestore-fs" {
  provider         = google-beta
  project          = google_project.fs.project_id
  name             = "(default)"
  # See available locations: https://firebase.google.com/docs/projects/locations#default-cloud-location
  location_id      = "name-of-region"
  # "FIRESTORE_NATIVE" is required to use Firestore with Firebase SDKs, authentication, and Firebase Security Rules.
  type             = "FIRESTORE_NATIVE"
  concurrency_mode = "OPTIMISTIC"

  # Wait for Firebase to be enabled in the Google Cloud project before initializing Firestore.
  depends_on = [
    google_firebase_project.fs,
  ]
}

# Creates a ruleset of Firestore Security Rules from a local file.
resource "google_firebaserules_ruleset" "firestore-fs" {
  provider = google-beta
  project  = google_project.fs.project_id
  source {
    files {
      # Write security rules in a local file named "firestore.rules".
      # Learn more: https://firebase.google.com/docs/firestore/security/get-started
      name = "firestore.rules"
      content = file("firestore.rules")
    }
  }

  # Wait for Firestore to be provisioned before creating this ruleset.
  depends_on = [
    google_firestore_database.firestore-fs
  ]
}

# Releases the ruleset for the Firestore instance.
resource "google_firebaserules_release" "firestore-fs" {
  provider     = google-beta
  name         = "cloud.firestore" # must be cloud.firestore
  ruleset_name = google_firebaserules_ruleset.firestore-fs.name
  project      = google_project.fs.project_id

  # Wait for Firestore to be provisioned before releasing the ruleset.
  depends_on = [
    google_firestore_database.firestore-fs,
  ]
}

#### Set up default Cloud Storage default bucket after Firestore ####

# Provisions the default Cloud Storage bucket for the project via Google App Engine.
resource "google_app_engine_application" "default-bucket-fs" {
  provider    = google-beta
  project     = google_project.fs.project_id
  # See available locations: https://firebase.google.com/docs/projects/locations#default-cloud-location
  # This will set the location for the default Storage bucket and the App Engine App.
  location_id = "name-of-region"  # Must be in the same location as Firestore (above)

  # Wait for Firestore to be provisioned first.
  # Otherwise, the Firestore instance will be provisioned in Datastore mode (unusable by Firebase).
  depends_on = [
    google_firestore_database.firestore-fs,
  ]
}

# Makes the default Storage bucket accessible for Firebase SDKs, authentication, and Firebase Security Rules.
resource "google_firebase_storage_bucket" "default-bucket-fs" {
  provider  = google-beta
  project   = google_project.fs.project_id
  bucket_id = google_app_engine_application.default-bucket-fs.default_bucket
}

# Creates a ruleset of Cloud Storage Security Rules from a local file.
resource "google_firebaserules_ruleset" "default-bucket-fs" {
  provider = google-beta
  project  = google_project.fs.project_id
  source {
    files {
      # Write security rules in a local file named "storage.rules".
      # Learn more: https://firebase.google.com/docs/storage/security/get-started
      name    = "storage.rules"
      content = file("storage.rules")
    }
  }

  # Wait for the Cloud Storage bucket to be provisioned before creating this ruleset.
  depends_on = [
    google_firebase_project.fs,
  ]
}

# Releases the ruleset to the default Storage bucket.
resource "google_firebaserules_release" "default-bucket-fs" {
  provider     = google-beta
  name         = "firebase.storage/${google_app_engine_application.default-bucket-fs.default_bucket}"
  ruleset_name = "projects/${google_project.fs.project_id}/rulesets/${google_firebaserules_ruleset.default-bucket-fs.name}"
  project      = google_project.fs.project_id
}

यह क्लाउड फायरस्टोर सुरक्षा नियमों का नियम है जो firestore.rules नामक स्थानीय फ़ाइल में होना चाहिए।

rules_version = '2';
service cloud.firestore {
  match /databases/{database}/documents {
    allow read: if request.auth != null;
    allow create: if request.auth != null;
    allow update: if request.auth != null;
  }
}

यह क्लाउड स्टोरेज सुरक्षा नियमों का नियम है जो storage.rules नामक स्थानीय फ़ाइल में होना चाहिए।

rules_version = '2';
service firebase.storage {
  match /b/{bucket}/o {
    match /{allPaths=**} {
      allow read, write: if request.auth != null;
    }
  }
}

फायरबेस ऐप चेक के साथ एपीआई संसाधन को सुरक्षित रखें

यह कॉन्फिगरेशन एक नया Google क्लाउड प्रोजेक्ट बनाता है, प्रोजेक्ट के लिए फायरबेस सेवाओं को सक्षम करता है, और क्लाउड फायरस्टोर के लिए फायरबेस ऐप चेक को सेट अप और लागू करने में सक्षम बनाता है ताकि इसे केवल आपके एंड्रॉइड ऐप से ही एक्सेस किया जा सके।

# Creates a new Google Cloud project.
resource "google_project" "appcheck" {
  provider   = google-beta.no_user_project_override
  folder_id  = "folder-id-for-new-project"
  name       = "Project Display Name"
  project_id = "project-id-for-new-project"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "services" {
  provider = google-beta.no_user_project_override
  project  = google_project.appcheck.project_id
  for_each = toset([
    "cloudresourcemanager.googleapis.com",
    "firebase.googleapis.com",
    "firebaseappcheck.googleapis.com",
    "firestore.googleapis.com",
    "serviceusage.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created earlier.
resource "google_firebase_project" "appcheck" {
  provider = google-beta
  project  = google_project.appcheck.project_id

  depends_on = [google_project_service.services]
}

# Provisions the Firestore database instance.
resource "google_firestore_database" "database" {
  provider = google-beta
  project  = google_firebase_project.appcheck.project
  name     = "(default)"
  # See available locations: https://firebase.google.com/docs/projects/locations#default-cloud-location
  location_id = "name-of-region"
  # "FIRESTORE_NATIVE" is required to use Firestore with Firebase SDKs, authentication, and Firebase Security Rules.
  type             = "FIRESTORE_NATIVE"
  concurrency_mode = "OPTIMISTIC"

  # Wait for Firebase to be enabled in the Google Cloud project before initializing Firestore.
  depends_on = [
    google_firebase_project.appcheck,
  ]
}

# Creates a Firebase Android App in the new project created earlier.
resource "google_firebase_android_app" "appcheck" {
  provider     = google-beta
  project      = google_firebase_project.appcheck.project
  display_name = "Play Integrity app"
  package_name = "package.name.playintegrity"
  sha256_hashes = [
    # TODO: insert your Android app's SHA256 certificate
  ]
}

# It takes a while for App Check to recognize the new app
# If your app already exists, you don't have to wait 30 seconds.
resource "time_sleep" "wait_30s" {
  depends_on      = [google_firebase_android_app.appcheck]
  create_duration = "30s"
}

# Register the Android app with the Play Integrity provider
resource "google_firebase_app_check_play_integrity_config" "appcheck" {
  provider = google-beta
  project  = google_firebase_project.appcheck.project
  app_id   = google_firebase_android_app.appcheck.app_id

  depends_on = [time_sleep.wait_30s, google_firestore_database.database]

  lifecycle {
    precondition {
      condition     = length(google_firebase_android_app.appcheck.sha256_hashes) > 0
      error_message = "Provide a SHA-256 certificate on the Android App to use App Check"
    }
  }
}

# Enable enforcement of App Check for Firestore
resource "google_firebase_app_check_service_config" "firestore" {
  provider = google-beta

  project    = google_firebase_project.appcheck.project
  service_id = "firestore.googleapis.com"

  depends_on = [google_project_service.services]
}

फ़ायरबेस एक्सटेंशन का एक उदाहरण स्थापित करें

यह कॉन्फ़िगरेशन एक नया Google क्लाउड प्रोजेक्ट बनाता है, प्रोजेक्ट के लिए फ़ायरबेस सेवाओं को सक्षम करता है, और प्रोजेक्ट में फ़ायरबेस एक्सटेंशन का एक नया उदाहरण स्थापित करता है। यदि उदाहरण पहले से मौजूद है, तो इसके पैरामीटर कॉन्फ़िगरेशन में दिए गए मानों के आधार पर अपडेट किए जाते हैं।

# Creates a new Google Cloud project.
resource "google_project" "extensions" {
  provider   = google-beta.no_user_project_override
  folder_id  = "folder-id-for-new-project"
  name       = "Project Display Name"
  project_id = "project-id-for-new-project"

  # Associates the project with a Cloud Billing account
  # (required to use Firebase Extensions).
  billing_account = "000000-000000-000000"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "extensions" {
  provider = google-beta.no_user_project_override
  project  = google_project.extensions.project_id
  for_each = toset([
    "cloudbilling.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "serviceusage.googleapis.com",
    "firebase.googleapis.com",
    "firebaseextensions.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "extensions" {
  provider = google-beta
  project  = google_project.extensions.project_id

  depends_on = [
    google_project_service.extensions,
  ]
}

# Installs an instance of the "Translate Text in Firestore" extension.
# Or updates the extension if the specified instance already exists.
resource "google_firebase_extensions_instance" "translation" {
  provider = google-beta
  project = google_project.extensions.project_id

  instance_id = "translate-text-in-firestore"
  config {
    extension_ref = "firebase/firestore-translate-text"

    params = {
      COLLECTION_PATH      = "posts/comments/translations"
      DO_BACKFILL          = true
      LANGUAGES            = "ar,en,es,de,fr"
      INPUT_FIELD_NAME     = "input"
      LANGUAGES_FIELD_NAME = "languages"
      OUTPUT_FIELD_NAME    = "translated"
    }

    system_params = {
      "firebaseextensions.v1beta.function/location"                   = "us-central1"
      "firebaseextensions.v1beta.function/memory"                     = "256"
      "firebaseextensions.v1beta.function/minInstances"               = "0"
      "firebaseextensions.v1beta.function/vpcConnectorEgressSettings" = "VPC_CONNECTOR_EGRESS_SETTINGS_UNSPECIFIED"
    }
  }
}

आप सभी विभिन्न प्रोजेक्ट-संबंधित विशेषताओं (जैसे project और user_project_override ) के बारे में अधिक जानना चाहते हैं

यह मार्गदर्शिका "प्रोजेक्ट्स" के साथ काम करते समय निम्नलिखित टेराफ़ॉर्म विशेषताओं का उपयोग करती है।

एक resource ब्लॉक के भीतर project

अनुशंसित: जब भी संभव हो, प्रत्येक resource ब्लॉक में project विशेषता शामिल करें

एक परियोजना विशेषता को शामिल करके, टेराफॉर्म निर्दिष्ट परियोजना के भीतर संसाधन ब्लॉक में निर्दिष्ट बुनियादी ढांचे का निर्माण करेगा। यह मार्गदर्शिका और हमारी नमूना कॉन्फ़िग फ़ाइलें सभी इस अभ्यास का उपयोग करती हैं।

project के बारे में आधिकारिक टेराफ़ॉर्म दस्तावेज़ देखें।

provider ब्लॉक के भीतर user_project_override

अधिकांश संसाधनों का प्रावधान करने के लिए, आपको user_project_override = true का उपयोग करना चाहिए, जिसका अर्थ है अपने स्वयं के फायरबेस प्रोजेक्ट के विरुद्ध कोटा की जाँच करना। हालाँकि, अपना नया प्रोजेक्ट सेट करने के लिए ताकि वह कोटा जाँच स्वीकार कर सके, आपको पहले user_project_override = false का उपयोग करना होगा।

user_project_override के बारे में आधिकारिक टेराफ़ॉर्म दस्तावेज़ देखें।

आपको यह त्रुटि मिलती है: generic::permission_denied: Firebase Tos Not Accepted ।

सुनिश्चित करें कि जिस उपयोगकर्ता खाते का उपयोग आप gCloud CLI कमांड चलाने के लिए कर रहे हैं, उसने फायरबेस सेवा की शर्तों (फायरबेस टीओएस) को स्वीकार कर लिया है।

• आप उपयोगकर्ता खाते में साइन इन ब्राउज़र का उपयोग करके और फायरबेस कंसोल में मौजूदा फायरबेस प्रोजेक्ट को देखने का प्रयास करके यह जांच कर सकते हैं। यदि आप किसी मौजूदा फायरबेस प्रोजेक्ट को देख सकते हैं, तो उपयोगकर्ता खाते ने फायरबेस टीओएस को स्वीकार कर लिया है।

• यदि आप किसी मौजूदा फायरबेस प्रोजेक्ट को नहीं देख पा रहे हैं, तो संभवतः उपयोगकर्ता खाते ने फायरबेस टीओएस को स्वीकार नहीं किया है। इसे ठीक करने के लिए, फायरबेस कंसोल के माध्यम से एक नया फायरबेस प्रोजेक्ट बनाएं और प्रोजेक्ट निर्माण के हिस्से के रूप में फायरबेस टीओएस को स्वीकार करें। आप कंसोल में प्रोजेक्ट सेटिंग्स के माध्यम से इस प्रोजेक्ट को तुरंत हटा सकते हैं।

terraform apply चलाने के बाद, आपको यह त्रुटि मिलती है: generic::permission_denied: IAM authority does not have the permission ।

कुछ मिनट प्रतीक्षा करें, और फिर terraform apply फिर से चलाने का प्रयास करें।

संसाधन का निर्माण विफल रहा, लेकिन जब आप terraform apply फिर से चलाते हैं, तो यह ALREADY_EXISTS कहता है।

यह विभिन्न प्रणालियों में प्रसार विलंब के कारण हो सकता है। terraform import चलाकर टेराफॉर्म स्थिति में संसाधन आयात करके इस समस्या को हल करने का प्रयास करें। फिर terraform apply दोबारा चलाने का प्रयास करें।

आप सीख सकते हैं कि प्रत्येक संसाधन को उसके टेराफ़ॉर्म दस्तावेज़ के "आयात" अनुभाग में कैसे आयात किया जाए (उदाहरण के लिए, क्लाउड फायरस्टोर के लिए "आयात" दस्तावेज़ )।

क्लाउड फायरस्टोर के साथ काम करते समय, आपको यह त्रुटि मिलती है: Error creating Index: googleapi: Error 409;...Concurrent access -- try again

जैसा कि त्रुटि से पता चलता है, हो सकता है कि टेराफ़ॉर्म एक ही समय में कई सूचकांकों को प्रावधानित करने और/या एक दस्तावेज़ बनाने का प्रयास कर रहा हो और एक समवर्ती त्रुटि का सामना करना पड़ा हो। terraform apply फिर से चलाने का प्रयास करें।

आपको यह त्रुटि मिलती है: "you may need to specify 'X-Goog-User-Project' HTTP header for quota and billing purposes"

इस त्रुटि का अर्थ है कि टेराफ़ॉर्म को नहीं पता कि किस प्रोजेक्ट के विरुद्ध कोटा की जाँच करनी है। समस्या निवारण के लिए, resource ब्लॉक में निम्नलिखित की जाँच करें:

• सुनिश्चित करें कि आपने project विशेषता के लिए एक मान निर्दिष्ट किया है।
• सुनिश्चित करें कि आप प्रदाता का उपयोग user_project_override = true (कोई उपनाम नहीं) के साथ कर रहे हैं, जो फायरबेस नमूनों में google-beta है।

नया Google क्लाउड प्रोजेक्ट बनाते समय, आपको त्रुटि मिलती है कि नए प्रोजेक्ट के लिए निर्दिष्ट प्रोजेक्ट आईडी पहले से मौजूद है।

प्रोजेक्ट आईडी पहले से मौजूद होने के संभावित कारण यहां दिए गए हैं:

• उस आईडी से जुड़ा प्रोजेक्ट किसी और का है।

  • समाधान के लिए: कोई अन्य प्रोजेक्ट आईडी चुनें।

• उस आईडी से जुड़ा प्रोजेक्ट हाल ही में हटा दिया गया था (सॉफ्ट-डिलीट स्थिति में)।

  • समाधान के लिए: यदि आपको लगता है कि आईडी से जुड़ा प्रोजेक्ट आपका है, तो projects.get REST API का उपयोग करके प्रोजेक्ट की स्थिति जांचें।

• उस आईडी से जुड़ा प्रोजेक्ट वर्तमान उपयोगकर्ता के अंतर्गत सही ढंग से मौजूद है। त्रुटि का संभावित कारण यह हो सकता है कि पिछला terraform apply बाधित हो गया हो।

  • हल करने के लिए: निम्नलिखित आदेश चलाएँ:
    terraform import google_project.default PROJECT_ID और तब
    terraform import google_firebase_project.default PROJECT_ID

क्लाउड फायरस्टोर और फिर क्लाउड स्टोरेज ( google_app_engine_application के माध्यम से) का प्रावधान करने का प्रयास करते समय, आपको यह त्रुटि मिलती है: Error: Error creating App Engine application: googleapi: Error 409: Cannot create Firestore database resource <resource-name> since it already exists at location <location-id>, alreadyExists ।

एक ऐप इंजन एप्लिकेशन के लिए क्लाउड फायरस्टोर इंस्टेंस की आवश्यकता होती है, लेकिन आपके पास प्रति प्रोजेक्ट केवल एक क्लाउड फायरस्टोर इंस्टेंस हो सकता है। इसलिए, जैसा कि त्रुटि संदेश से पता चलता है, यदि आपने पहले ही प्रोजेक्ट के क्लाउड फायरस्टोर इंस्टेंस को एक स्थान पर प्रावधानित कर दिया है, तो यदि आप क्लाउड फायरस्टोर इंस्टेंस को किसी भिन्न स्थान पर प्रावधान करने का प्रयास करेंगे तो ऐप इंजन त्रुटि करेगा। ऐप इंजन को लगता है कि आप पहले से मौजूद क्लाउड फायरस्टोर इंस्टेंस को "पुनः प्रावधानित" करने का प्रयास कर रहे हैं।

इस त्रुटि को हल करने के लिए, क्लाउड फायरस्टोर और ऐप इंजन एप्लिकेशन दोनों के लिए एक ही स्थान का उपयोग करें। यदि आपको क्लाउड फायरस्टोर से भिन्न स्थान पर क्लाउड स्टोरेज बकेट की आवश्यकता है, तो आप अतिरिक्त बकेट का प्रावधान कर सकते हैं ( एकाधिक क्लाउड स्टोरेज बकेट बनाने के लिए नमूना कॉन्फ़िगरेशन देखें)।

क्लाउड स्टोरेज ( google_app_engine_application के माध्यम से) और फिर क्लाउड फायरस्टोर का प्रावधान करने का प्रयास करते समय, आपको यह त्रुटि मिलती है: Error: Error creating Database: googleapi: Error 409: Database already exists. Please use another database_id ।

जब आप किसी प्रोजेक्ट के डिफ़ॉल्ट क्लाउड स्टोरेज बकेट ( google_app_engine_application माध्यम से) का प्रावधान करते हैं और प्रोजेक्ट में अभी तक क्लाउड फायरस्टोर इंस्टेंस नहीं है, तो google_app_engine_application स्वचालित रूप से प्रोजेक्ट के क्लाउड फायरस्टोर इंस्टेंस का प्रावधान करता है।

इसलिए, यदि आपके प्रोजेक्ट का क्लाउड फायरस्टोर इंस्टेंस पहले से ही प्रावधानित है, तो यदि आप क्लाउड फायरस्टोर इंस्टेंस को स्पष्ट रूप से प्रावधान करने का प्रयास करेंगे तो google_firestore_database त्रुटि देगा।

एक बार प्रोजेक्ट के क्लाउड फायरस्टोर इंस्टेंस का प्रावधान हो जाने के बाद, आप इसे "पुनः प्रावधान" नहीं कर सकते या इसका स्थान नहीं बदल सकते। त्रुटि को होने से रोकने के लिए, अपनी कॉन्फ़िगरेशन फ़ाइल से google_firestore_database संसाधन ब्लॉक को हटा दें। ध्यान दें, हालाँकि, हम प्रोजेक्ट के डिफ़ॉल्ट क्लाउड स्टोरेज बकेट से पहले क्लाउड फायरस्टोर का प्रावधान करने की सलाह देते हैं (क्यों के लिए नीचे एक तरफ देखें)।