เริ่มต้นใช้งาน Terraform และ Firebase

ดูเวอร์ชันที่มีคำอธิบายประกอบสูงของไฟล์กำหนดค่าตัวอย่างนี้

หากคุณไม่คุ้นเคยกับโครงสร้างพื้นฐานของโปรเจ็กต์และแอปที่เป็นทรัพยากร โปรดตรวจสอบเอกสารประกอบต่อไปนี้:

• ทำความเข้าใจโปรเจ็กต์ Firebase
• เอกสารอ้างอิง สำหรับการจัดการโครงการ Firebase

# Terraform configuration to set up providers by version.
...

# Configures the provider to use the resource block's specified project for quota checks.
...

# Configures the provider to not use the resource block's specified project for quota checks.
...

# Creates a new Google Cloud project.
resource "google_project" "default" {
  # Use the provider that enables the setup of quota checks for a new project
  provider   = google-beta.no_user_project_override

  name            = "Project Display Name"        // learn more about the project name
  project_id      = "project-id-for-new-project"  // learn more about the project ID
  # Required for any service that requires the Blaze pricing plan
  # (like Firebase Authentication with GCIP)
  billing_account = "000000-000000-000000"

  # Required for the project to display in any list of Firebase projects.
  labels = {
    "firebase" = "enabled"  // learn more about the Firebase-enabled label
  }
}

# Enables required APIs.
resource "google_project_service" "default" {
  # Use the provider without quota checks for enabling APIS
  provider = google-beta.no_user_project_override
  project  = google_project.default.project_id
  for_each = toset([
    "cloudbilling.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "firebase.googleapis.com",
    # Enabling the ServiceUsage API allows the new project to be quota checked from now on.
    "serviceusage.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
# This action essentially "creates a Firebase project" and allows the project to use
# Firebase services (like Firebase Authentication) and
# Firebase tooling (like the Firebase console).
# Learn more about the relationship between Firebase projects and Google Cloud.
resource "google_firebase_project" "default" {
  # Use the provider that performs quota checks from now on
  provider = google-beta

  project  = google_project.default.project_id

  # Waits for the required APIs to be enabled.
  depends_on = [
    google_project_service.default
  ]
}

# Creates a Firebase Android App in the new project created above.
# Learn more about the relationship between Firebase Apps and Firebase projects.
resource "google_firebase_android_app" "default" {
  provider = google-beta

  project      = google_project.default.project_id
  display_name = "My Awesome Android app"  # learn more about an app's display name
  package_name = "awesome.package.name"    # learn more about an app's package name

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.default,
  ]
}

ตั้งค่าการตรวจสอบสิทธิ์ Firebase ด้วย GCIP

การกำหนดค่านี้จะสร้างโปรเจ็กต์ Google Cloud ใหม่ เชื่อมโยงโปรเจ็กต์กับบัญชี Cloud Billing (ต้องใช้แผนราคา Blaze สำหรับการตรวจสอบสิทธิ์ Firebase ด้วย GCIP) เปิดใช้บริการ Firebase สำหรับโปรเจ็กต์ ตั้งค่าการตรวจสอบสิทธิ์ Firebase ด้วย GCIP และลงทะเบียนแอปที่แตกต่างกัน 3 แอป ประเภทกับโครงการ

โปรดทราบว่าจำเป็นต้องเปิดใช้ GCIP เพื่อตั้งค่า Firebase Authentication ผ่าน Terraform

# Creates a new Google Cloud project.
resource "google_project" "auth" {
  provider  = google-beta.no_user_project_override
  folder_id = "folder-id-for-new-project"
  name            = "Project Display Name"
  project_id      = "project-id-for-new-project"

  # Associates the project with a Cloud Billing account
  # (required for Firebase Authentication with GCIP).
  billing_account = "000000-000000-000000"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "auth" {
  provider = google-beta.no_user_project_override
  project  = google_project.auth.project_id
  for_each = toset([
    "cloudbilling.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "serviceusage.googleapis.com",
    "identitytoolkit.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "auth" {
  provider = google-beta
  project  = google_project.auth.project_id

  depends_on = [
    google_project_service.auth,
  ]
}

# Creates an Identity Platform config.
# Also enables Firebase Authentication with Identity Platform in the project if not.
resource "google_identity_platform_config" "auth" {
  provider = google-beta
  project  = google_project.auth.project_id

  # Auto-deletes anonymous users
  autodelete_anonymous_users = true

  # Configures local sign-in methods, like anonymous, email/password, and phone authentication.
  sign_in {
    allow_duplicate_emails = true

    anonymous {
      enabled = true
    }

    email {
      enabled = true
      password_required = false
    }

    phone_number {
      enabled = true
      test_phone_numbers = {
        "+11231231234" = "000000"
      }
    }
  }

  # Sets an SMS region policy.
  sms_region_config {
    allowlist_only {
      allowed_regions = [
        "US",
        "CA",
      ]
    }
  }

  # Configures blocking functions.
  blocking_functions {
    triggers {
      event_type = "beforeSignIn"
      function_uri = "https://us-east1-${google_project.auth.project_id}.cloudfunctions.net/before-sign-in"
    }
    forward_inbound_credentials {
      refresh_token = true
      access_token = true
      id_token = true
    }
  }

  # Configures a temporary quota for new signups for anonymous, email/password, and phone number.
  quota {
    sign_up_quota_config {
      quota = 1000
      start_time = ""
      quota_duration = "7200s"
    }
  }

  # Configures authorized domains.
  authorized_domains = [
    "localhost",
    "${google_project.auth.project_id}.firebaseapp.com",
    "${google_project.auth.project_id}.web.app",
  ]

  # Wait for identitytoolkit.googleapis.com to be enabled before initializing Authentication.
  depends_on = [
    google_project_service.auth,
  ]
}

# Creates a Firebase Android App in the new project created above.
resource "google_firebase_android_app" "auth" {
  provider     = google-beta
  project      = google_project.auth.project_id
  display_name = "My Android app"
  package_name = "android.package.name"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.auth,
  ]
}

# Creates a Firebase Apple-platforms App in the new project created above.
resource "google_firebase_apple_app" "auth" {
  provider     = google-beta
  project      = google_project.auth.project_id
  display_name = "My Apple app"
  bundle_id    = "apple.app.12345"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.auth,
  ]
}

# Creates a Firebase Web App in the new project created above.
resource "google_firebase_web_app" "auth" {
  provider     = google-beta
  project      = google_project.auth.project_id
  display_name = "My Web app"

  # The other App types (Android and Apple) use "DELETE" by default.
  # Web apps don't use "DELETE" by default due to backward-compatibility.
  deletion_policy = "DELETE"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.auth,
  ]
}

จัดเตรียมอินสแตนซ์ Firebase Realtime Database เริ่มต้น

การกำหนดค่านี้จะสร้างโปรเจ็กต์ Google Cloud ใหม่ เปิดใช้บริการ Firebase สำหรับโปรเจ็กต์ จัดเตรียมอินสแตนซ์ฐานข้อมูลเรียลไทม์เริ่มต้นของโปรเจ็กต์ และลงทะเบียนแอป 3 ประเภทที่แตกต่างกันกับโปรเจ็กต์

# Creates a new Google Cloud project.
resource "google_project" "rtdb" {
  provider   = google-beta.no_user_project_override
  folder_id  = "folder-id-for-new-project"
  name       = "Project Display Name"
  project_id = "project-id-for-new-project"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "rtdb" {
  provider = google-beta.no_user_project_override
  project  = google_project.rtdb.project_id
  for_each = toset([
    "serviceusage.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "firebasedatabase.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "rtdb" {
  provider = google-beta
  project  = google_project.rtdb.project_id
}

# Provisions the default Realtime Database default instance.
resource "google_firebase_database_instance" "database" {
  provider    = google-beta
  project     = google_project.rtdb.project_id
  # See available locations: https://firebase.google.com/docs/projects/locations#rtdb-locations
  region      = "name-of-region"
  # This value will become the first segment of the database's URL.
  instance_id = "${google_project.rtdb.project_id}-default-rtdb"
  type        = "DEFAULT_DATABASE"

  # Wait for Firebase to be enabled in the Google Cloud project before initializing Realtime Database.
  depends_on = [
    google_firebase_project.rtdb,
  ]
}

# Creates a Firebase Android App in the new project created above.
resource "google_firebase_android_app" "rtdb" {
  provider     = google-beta
  project      = google_project.rtdb.project_id
  display_name = "My Android app"
  package_name = "android.package.name"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.rtdb,
  ]
}

# Creates a Firebase Apple-platforms App in the new project created above.
resource "google_firebase_apple_app" "rtdb" {
  provider     = google-beta
  project      = google_project.rtdb.project_id
  display_name = "My Apple app"
  bundle_id    = "apple.app.12345"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.rtdb,
  ]
}

# Creates a Firebase Web App in the new project created above.
resource "google_firebase_web_app" "rtdb" {
  provider     = google-beta
  project      = google_project.rtdb.project_id
  display_name = "My Web app"

  # The other App types (Android and Apple) use "DELETE" by default.
  # Web apps don't use "DELETE" by default due to backward-compatibility.
  deletion_policy = "DELETE"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.rtdb,
  ]
}

จัดเตรียมอินสแตนซ์ฐานข้อมูลเรียลไทม์ Firebase หลายรายการ

การกำหนดค่านี้จะสร้างโปรเจ็กต์ Google Cloud ใหม่ เชื่อมโยงโปรเจ็กต์กับบัญชี Cloud Billing (ต้องใช้แผนราคา Blaze สำหรับอินสแตนซ์ฐานข้อมูลเรียลไทม์หลายรายการ) เปิดใช้บริการ Firebase สำหรับโปรเจ็กต์ จัดเตรียมอินสแตนซ์ฐานข้อมูลเรียลไทม์หลายรายการ (รวมถึงฐานข้อมูลเรียลไทม์เริ่มต้นของโปรเจ็กต์ด้วย อินสแตนซ์) และลงทะเบียนแอปสามประเภทที่แตกต่างกันกับโปรเจ็กต์

# Creates a new Google Cloud project.
resource "google_project" "rtdb-multi" {
  provider   = google-beta.no_user_project_override
  folder_id  = "folder-id-for-new-project"
  name       = "Project Display Name"
  project_id = "project-id-for-new-project"

  # Associate the project with a Cloud Billing account
  # (required for multiple Realtime Database instances).
  billing_account = "000000-000000-000000"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "rtdb-multi" {
  provider = google-beta.no_user_project_override
  project  = google_project.rtdb-multi.project_id
  for_each = toset([
    "cloudbilling.googleapis.com",
    "serviceusage.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "firebasedatabase.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "rtdb-multi" {
  provider = google-beta
  project  = google_project.rtdb-multi.project_id
}

# Provisions the default Realtime Database default instance.
resource "google_firebase_database_instance" "database-default" {
  provider    = google-beta
  project     = google_project.rtdb-multi.project_id
  # See available locations: https://firebase.google.com/docs/projects/locations#rtdb-locations
  region      = "name-of-region"
  # This value will become the first segment of the database's URL.
  instance_id = "${google_project.rtdb-multi.project_id}-default-rtdb"
  type        = "DEFAULT_DATABASE"

  # Wait for Firebase to be enabled in the Google Cloud project before initializing Realtime Database.
  depends_on = [
    google_firebase_project.rtdb-multi,
  ]
}

# Provisions an additional Realtime Database instance.
resource "google_firebase_database_instance" "database-additional" {
  provider    = google-beta
  project     = google_project.rtdb-multi.project_id
  # See available locations: https://firebase.google.com/docs/projects/locations#rtdb-locations
  # This location doesn't need to be the same as the default database instance.
  region      = "name-of-region"
  # This value will become the first segment of the database's URL.
  instance_id = "name-of-additional-database-instance"
  type        = "USER_DATABASE"

  # Wait for Firebase to be enabled in the Google Cloud project before initializing Realtime Database.
  depends_on = [
    google_firebase_project.rtdb-multi,
  ]
}

# Creates a Firebase Android App in the new project created above.
resource "google_firebase_android_app" "rtdb-multi" {
  provider     = google-beta
  project      = google_project.rtdb-multi.project_id
  display_name = "My Android app"
  package_name = "android.package.name"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.rtdb-multi,
  ]
}

# Creates a Firebase Apple-platforms App in the new project created above.
resource "google_firebase_apple_app" "rtdb-multi" {
  provider     = google-beta
  project      = google_project.rtdb-multi.project_id
  display_name = "My Apple app"
  bundle_id    = "apple.app.12345"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.rtdb-multi,
  ]
}

# Creates a Firebase Web App in the new project created above.
resource "google_firebase_web_app" "rtdb-multi" {
  provider     = google-beta
  project      = google_project.rtdb-multi.project_id
  display_name = "My Web app"

  # The other App types (Android and Apple) use "DELETE" by default.
  # Web apps don't use "DELETE" by default due to backward-compatibility.
  deletion_policy = "DELETE"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.rtdb-multi,
  ]
}

จัดเตรียมอินสแตนซ์ Cloud Firestore

การกำหนดค่านี้จะสร้างโปรเจ็กต์ Google Cloud ใหม่ เปิดใช้บริการ Firebase สำหรับโปรเจ็กต์ จัดเตรียมอินสแตนซ์ Cloud Firestore ของโปรเจ็กต์ และลงทะเบียนแอปสามประเภทที่แตกต่างกันกับโปรเจ็กต์

นอกจากนี้ยังจัดเตรียมกฎความปลอดภัย Firebase สำหรับอินสแตนซ์ Cloud Firestore สร้างดัชนี Cloud Firestore และเพิ่มเอกสาร Cloud Firestore พร้อมข้อมูลเริ่มต้น

# Creates a new Google Cloud project.
resource "google_project" "firestore" {
  provider   = google-beta.no_user_project_override
  folder_id  = "folder-id-for-new-project"
  name       = "Project Display Name"
  project_id = "project-id-for-new-project"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "firestore" {
  provider = google-beta.no_user_project_override
  project  = google_project.firestore.project_id
  for_each = toset([
    "cloudresourcemanager.googleapis.com",
    "serviceusage.googleapis.com",
    "firestore.googleapis.com",
    "firebaserules.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "firestore" {
  provider = google-beta
  project  = google_project.firestore.project_id
}

# Provisions the Firestore database instance.
resource "google_firestore_database" "firestore" {
  provider                    = google-beta
  project                     = google_project.firestore.project_id
  name                        = "(default)"
  # See available locations: https://firebase.google.com/docs/projects/locations#default-cloud-location
  location_id                 = "name-of-region"
  # "FIRESTORE_NATIVE" is required to use Firestore with Firebase SDKs, authentication, and Firebase Security Rules.
  type                        = "FIRESTORE_NATIVE"
  concurrency_mode            = "OPTIMISTIC"

  # Wait for Firebase to be enabled in the Google Cloud project before initializing Firestore.
  depends_on = [
    google_firebase_project.firestore,
  ]
}

# Creates a ruleset of Firestore Security Rules from a local file.
resource "google_firebaserules_ruleset" "firestore" {
  provider = google-beta
  project  = google_project.firestore.project_id
  source {
    files {
      name = "firestore.rules"
      # Write security rules in a local file named "firestore.rules".
      # Learn more: https://firebase.google.com/docs/firestore/security/get-started
      content = file("firestore.rules")
    }
  }

  # Wait for Firestore to be provisioned before creating this ruleset.
  depends_on = [
    google_firestore_database.firestore,
  ]
}

# Releases the ruleset for the Firestore instance.
resource "google_firebaserules_release" "firestore" {
  provider     = google-beta
  name         = "cloud.firestore"  # must be cloud.firestore
  ruleset_name = google_firebaserules_ruleset.firestore.name
  project      = google_project.firestore.project_id

  # Wait for Firestore to be provisioned before releasing the ruleset.
  depends_on = [
    google_firestore_database.firestore,
  ]
}

# Adds a new Firestore index.
resource "google_firestore_index" "indexes" {
  provider = google-beta
  project  = google_project.firestore.project_id

  collection  = "quiz"
  query_scope = "COLLECTION"

  fields {
    field_path = "question"
    order      = "ASCENDING"
  }

  fields {
    field_path = "answer"
    order      = "ASCENDING"
  }

  # Wait for Firestore to be provisioned before adding this index.
  depends_on = [
    google_firestore_database.firestore,
  ]
}

# Adds a new Firestore document with seed data.
# Don't use real end-user or production data in this seed document.
resource "google_firestore_document" "doc" {
  provider    = google-beta
  project     = google_project.firestore.project_id
  collection  = "quiz"
  document_id = "question-1"
  fields      = "{\"question\":{\"stringValue\":\"Favorite Database\"},\"answer\":{\"stringValue\":\"Firestore\"}}"

  # Wait for Firestore to be provisioned before adding this document.
  depends_on = [
    google_firestore_database.firestore,
  ]
}

# Creates a Firebase Android App in the new project created above.
resource "google_firebase_android_app" "firestore" {
  provider     = google-beta
  project      = google_project.firestore.project_id
  display_name = "My Android app"
  package_name = "android.package.name"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.firestore,
  ]
}

# Creates a Firebase Apple-platforms App in the new project created above.
resource "google_firebase_apple_app" "firestore" {
  provider     = google-beta
  project      = google_project.firestore.project_id
  display_name = "My Apple app"
  bundle_id    = "apple.app.12345"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.firestore,
  ]
}

# Creates a Firebase Web App in the new project created above.
resource "google_firebase_web_app" "firestore" {
  provider     = google-beta
  project      = google_project.firestore.project_id
  display_name = "My Web app"

  # The other App types (Android and Apple) use "DELETE" by default.
  # Web apps don't use "DELETE" by default due to backward-compatibility.
  deletion_policy = "DELETE"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.firestore,
  ]
}

นี่คือชุดกฎของกฎความปลอดภัยของ Cloud Firestore ที่ควรอยู่ในไฟล์ในเครื่องชื่อ firestore.rules

rules_version = '2';
service cloud.firestore {
  match /databases/{database}/documents {
    allow read: if request.auth != null;
    allow create: if request.auth != null;
    allow update: if request.auth != null;
  }
}

จัดสรรที่เก็บข้อมูล Cloud Storage เริ่มต้น

การกำหนดค่านี้จะสร้างโปรเจ็กต์ Google Cloud ใหม่ เปิดใช้บริการ Firebase สำหรับโปรเจ็กต์ จัดเตรียมที่เก็บข้อมูล Cloud Storage เริ่มต้นของโปรเจ็กต์ และลงทะเบียนแอป 3 ประเภทที่แตกต่างกันกับโปรเจ็กต์

นอกจากนี้ยังจัดเตรียมกฎความปลอดภัย Firebase สำหรับที่เก็บข้อมูล Cloud Storage และอัปโหลดไฟล์ไปยังที่เก็บข้อมูล

# Creates a new Google Cloud project.
resource "google_project" "storage" {
  provider   = google-beta.no_user_project_override
  folder_id  = "folder-id-for-new-project"
  name       = "Project Display Name"
  project_id = "project-id-for-new-project"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "storage" {
  provider = google-beta.no_user_project_override
  project  = google_project.storage.project_id
  for_each = toset([
    "serviceusage.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "firebaserules.googleapis.com",
    "firebasestorage.googleapis.com",
    "storage.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "storage" {
  provider = google-beta
  project  = google_project.storage.project_id
}

# Provisions the default Cloud Storage bucket for the project via Google App Engine.
resource "google_app_engine_application" "default" {
  provider    = google-beta
  project     = google_project.storage.project_id
  # See available locations: https://firebase.google.com/docs/projects/locations#default-cloud-location
  # This will set the location for the default Storage bucket and the App Engine App.
  location_id = "name-of-region-for-default-bucket"

  # If you use Firestore, uncomment this to make sure Firestore is provisioned first.
  # depends_on = [
    # google_firestore_database.firestore
  # ]
}

# Makes the default Storage bucket accessible for Firebase SDKs, authentication, and Firebase Security Rules.
resource "google_firebase_storage_bucket" "default-bucket" {
  provider  = google-beta
  project   = google_project.storage.project_id
  bucket_id = google_app_engine_application.default.default_bucket
}

# Creates a ruleset of Cloud Storage Security Rules from a local file.
resource "google_firebaserules_ruleset" "storage" {
  provider = google-beta
  project  = google_project.storage.project_id
  source {
    files {
      # Write security rules in a local file named "storage.rules".
      # Learn more: https://firebase.google.com/docs/storage/security/get-started
      name    = "storage.rules"
      content = file("storage.rules")
    }
  }

  # Wait for the default Storage bucket to be provisioned before creating this ruleset.
  depends_on = [
    google_firebase_project.storage,
  ]
}

# Releases the ruleset to the default Storage bucket.
resource "google_firebaserules_release" "default-bucket" {
  provider     = google-beta
  name         = "firebase.storage/${google_app_engine_application.default.default_bucket}"
  ruleset_name = "projects/${google_project.storage.project_id}/rulesets/${google_firebaserules_ruleset.storage.name}"
  project      = google_project.storage.project_id
}

# Uploads a new file to the default Storage bucket.
# Don't use real end-user or production data in this file.
resource "google_storage_bucket_object" "cat-picture" {
  provider = google-beta
  name     = "cat.png"
  source   = "path/to/cat.png"
  bucket   = google_app_engine_application.default.default_bucket
}

# Creates a Firebase Android App in the new project created above.
resource "google_firebase_android_app" "storage" {
  provider     = google-beta
  project      = google_project.storage.project_id
  display_name = "My Android app"
  package_name = "android.package.name"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.storage,
  ]
}

# Creates a Firebase Apple-platforms App in the new project created above.
resource "google_firebase_apple_app" "storage" {
  provider     = google-beta
  project      = google_project.storage.project_id
  display_name = "My Apple app"
  bundle_id    = "apple.app.12345"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.storage,
  ]
}

# Creates a Firebase Web App in the new project created above.
resource "google_firebase_web_app" "storage" {
  provider     = google-beta
  project      = google_project.storage.project_id
  display_name = "My Web app"

  # The other App types (Android and Apple) use "DELETE" by default.
  # Web apps don't use "DELETE" by default due to backward-compatibility.
  deletion_policy = "DELETE"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.storage,
  ]
}

นี่คือชุดกฎของกฎการรักษาความปลอดภัยของ Cloud Storage ที่ควรอยู่ในไฟล์ในเครื่องชื่อ storage.rules

rules_version = '2';
service firebase.storage {
  match /b/{bucket}/o {
    match /{allPaths=**} {
      allow read, write: if request.auth != null;
    }
  }
}

จัดสรรที่เก็บข้อมูล Cloud Storage หลายรายการ

การกำหนดค่านี้จะสร้างโปรเจ็กต์ Google Cloud ใหม่ เชื่อมโยงโปรเจ็กต์กับบัญชี Cloud Billing (ต้องใช้แผนราคา Blaze สำหรับที่เก็บข้อมูลหลายรายการ) เปิดใช้บริการ Firebase สำหรับโปรเจ็กต์ จัดเตรียมที่เก็บข้อมูล Cloud Storage หลายรายการ (รวมถึงที่เก็บข้อมูล Cloud Storage เริ่มต้นของโปรเจ็กต์) และลงทะเบียนแอปสามประเภทที่แตกต่างกันกับโปรเจ็กต์

นอกจากนี้ยังจัดเตรียมกฎความปลอดภัยของ Firebase สำหรับที่เก็บข้อมูล Cloud Storage และอัปโหลดไฟล์ไปยังที่เก็บข้อมูล Cloud Storage เริ่มต้น

# Creates a new Google Cloud project.
resource "google_project" "storage-multi" {
  provider  = google-beta.no_user_project_override
  folder_id = "folder-id-for-new-project"
  name            = "Project Display Name"
  project_id      = "project-id-for-new-project"

  # Associates the project with a Cloud Billing account
  # (required for multiple Cloud Storage buckets).
  billing_account = "000000-000000-000000"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "storage-multi" {
  provider = google-beta.no_user_project_override
  project  = google_project.storage-multi.project_id
  for_each = toset([
    "cloudbilling.googleapis.com",
    "serviceusage.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "firebaserules.googleapis.com",
    "firebasestorage.googleapis.com",
    "storage.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "storage-multi" {
  provider = google-beta
  project  = google_project.storage-multi.project_id
}

# Provisions the default Cloud Storage bucket for the project via Google App Engine.
resource "google_app_engine_application" "default-multi" {
  provider = google-beta
  project  = google_project.storage-multi.project_id
  # See available locations: https://firebase.google.com/docs/projects/locations#default-cloud-location
  # This will set the location for the default Storage bucket and the App Engine App.
  location_id = "name-of-region-for-default-bucket"

  # If you use Firestore, uncomment this to make sure Firestore is provisioned first.
  # depends_on = [
  # google_firestore_database.firestore
  # ]
}

# Provisions an additional Cloud Storage bucket.
# Additional Cloud Storage buckets are not provisioned via App Engine.
resource "google_storage_bucket" "bucket-multi" {
  provider = google-beta
  project  = google_project.storage-multi.project_id
  name     = "name-of-additional-storage-bucket"
  # See available locations: https://cloud.google.com/storage/docs/locations#available-locations
  # This location does not need to be the same as the default Storage bucket.
  location = "name-of-region-for-additional-bucket"
}

# Makes the default Storage bucket accessible for Firebase SDKs, authentication, and Firebase Security Rules.
resource "google_firebase_storage_bucket" "default-bucket-multi" {
  provider  = google-beta
  project   = google_project.storage-multi.project_id
  bucket_id = google_app_engine_application.default-multi.default_bucket
}

# Makes the additional Storage bucket accessible for Firebase SDKs, authentication, and Firebase Security Rules.
resource "google_firebase_storage_bucket" "bucket-multi" {
  provider  = google-beta
  project   = google_project.storage-multi.project_id
  bucket_id = google_storage_bucket.bucket-multi.name
}

# Creates a ruleset of Firebase Security Rules from a local file.
resource "google_firebaserules_ruleset" "storage-multi" {
  provider = google-beta
  project  = google_project.storage-multi.project_id
  source {
    files {
      # Write security rules in a local file named "storage.rules"
      # Learn more: https://firebase.google.com/docs/storage/security/get-started
      name    = "storage.rules"
      content = file("storage.rules")
    }
  }

  # Wait for the Storage buckets to be provisioned before creating this ruleset.
  depends_on = [
    google_firebase_project.storage-multi,
  ]
}

# Releases the ruleset to the default Storage bucket.
resource "google_firebaserules_release" "default-bucket-multi" {
  provider     = google-beta
  name         = "firebase.storage/${google_app_engine_application.default-multi.default_bucket}"
  ruleset_name = "projects/${google_project.storage-multi.project_id}/rulesets/${google_firebaserules_ruleset.storage-multi.name}"
  project      = google_project.storage-multi.project_id
}

# Releases the ruleset to the additional Storage bucket.
resource "google_firebaserules_release" "bucket-multi" {
  provider     = google-beta
  name         = "firebase.storage/${google_storage_bucket.bucket-multi.name}"
  ruleset_name = "projects/${google_project.storage-multi.project_id}/rulesets/${google_firebaserules_ruleset.storage-multi.name}"
  project      = google_project.storage-multi.project_id
}

# Uploads a new file to the default Storage bucket.
# Do not use real end-user or production data in this file.
resource "google_storage_bucket_object" "cat-picture-multi" {
  provider = google-beta
  name     = "cat.png"
  source   = "path/to/cat.png"
  bucket   = google_app_engine_application.default-multi.default_bucket
}

# Creates a Firebase Android App in the new project created above.
resource "google_firebase_android_app" "storage-multi" {
  provider     = google-beta
  project      = google_project.storage-multi.project_id
  display_name = "My Android app"
  package_name = "android.package.name"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.storage-multi,
  ]
}

# Creates a Firebase Apple-platforms App in the new project created above.
resource "google_firebase_apple_app" "storage-multi" {
  provider     = google-beta
  project      = google_project.storage-multi.project_id
  display_name = "My Apple app"
  bundle_id    = "apple.app.12345"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.storage-multi,
  ]
}

# Creates a Firebase Web App in the new project created above.
resource "google_firebase_web_app" "storage-multi" {
  provider     = google-beta
  project      = google_project.storage-multi.project_id
  display_name = "My Web app"

  # The other App types (Android and Apple) use "DELETE" by default.
  # Web apps don't use "DELETE" by default due to backward-compatibility.
  deletion_policy = "DELETE"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.storage-multi,
  ]
}

นี่คือชุดกฎของกฎการรักษาความปลอดภัยของ Cloud Storage ที่ควรอยู่ในไฟล์ในเครื่องชื่อ storage.rules

rules_version = '2';
service firebase.storage {
  match /b/{bucket}/o {
    match /{allPaths=**} {
      allow read, write: if request.auth != null;
    }
  }
}

จัดเตรียมอินสแตนซ์ Cloud Firestore และที่เก็บข้อมูล Cloud Storage เริ่มต้น

การกำหนดค่านี้จะสร้างโปรเจ็กต์ Google Cloud ใหม่ เปิดใช้บริการ Firebase สำหรับโปรเจ็กต์ จัดเตรียมอินสแตนซ์ Cloud Firestore จากนั้นจัดเตรียมที่เก็บข้อมูล Cloud Storage เริ่มต้น

นอกจากนี้ยังจัดเตรียมกฎความปลอดภัยของ Firebase สำหรับอินสแตนซ์ Cloud Firestore และที่เก็บข้อมูล Cloud Storage เริ่มต้นอีกด้วย

# Creates a new Google Cloud project.
resource "google_project" "fs" {  # fs = Firestore + Storage
  provider   = google-beta.no_user_project_override
  folder_id  = "folder-id-for-new-project"
  name       = "Project Display Name"
  project_id = "project-id-for-new-project"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "fs" {
  provider = google-beta.no_user_project_override
  project  = google_project.fs.project_id
  for_each = toset([
    "serviceusage.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "firebaserules.googleapis.com",
    "firebasestorage.googleapis.com",
    "storage.googleapis.com",
    "firestore.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "fs" {
  provider = google-beta
  project  = google_project.fs.project_id

}

#### Set up Firestore before default Cloud Storage bucket ####

# Provisions the Firestore database instance.
resource "google_firestore_database" "firestore-fs" {
  provider         = google-beta
  project          = google_project.fs.project_id
  name             = "(default)"
  # See available locations: https://firebase.google.com/docs/projects/locations#default-cloud-location
  location_id      = "name-of-region"
  # "FIRESTORE_NATIVE" is required to use Firestore with Firebase SDKs, authentication, and Firebase Security Rules.
  type             = "FIRESTORE_NATIVE"
  concurrency_mode = "OPTIMISTIC"

  # Wait for Firebase to be enabled in the Google Cloud project before initializing Firestore.
  depends_on = [
    google_firebase_project.fs,
  ]
}

# Creates a ruleset of Firestore Security Rules from a local file.
resource "google_firebaserules_ruleset" "firestore-fs" {
  provider = google-beta
  project  = google_project.fs.project_id
  source {
    files {
      # Write security rules in a local file named "firestore.rules".
      # Learn more: https://firebase.google.com/docs/firestore/security/get-started
      name = "firestore.rules"
      content = file("firestore.rules")
    }
  }

  # Wait for Firestore to be provisioned before creating this ruleset.
  depends_on = [
    google_firestore_database.firestore-fs
  ]
}

# Releases the ruleset for the Firestore instance.
resource "google_firebaserules_release" "firestore-fs" {
  provider     = google-beta
  name         = "cloud.firestore" # must be cloud.firestore
  ruleset_name = google_firebaserules_ruleset.firestore-fs.name
  project      = google_project.fs.project_id

  # Wait for Firestore to be provisioned before releasing the ruleset.
  depends_on = [
    google_firestore_database.firestore-fs,
  ]
}

#### Set up default Cloud Storage default bucket after Firestore ####

# Provisions the default Cloud Storage bucket for the project via Google App Engine.
resource "google_app_engine_application" "default-bucket-fs" {
  provider    = google-beta
  project     = google_project.fs.project_id
  # See available locations: https://firebase.google.com/docs/projects/locations#default-cloud-location
  # This will set the location for the default Storage bucket and the App Engine App.
  location_id = "name-of-region"  # Must be in the same location as Firestore (above)

  # Wait for Firestore to be provisioned first.
  # Otherwise, the Firestore instance will be provisioned in Datastore mode (unusable by Firebase).
  depends_on = [
    google_firestore_database.firestore-fs,
  ]
}

# Makes the default Storage bucket accessible for Firebase SDKs, authentication, and Firebase Security Rules.
resource "google_firebase_storage_bucket" "default-bucket-fs" {
  provider  = google-beta
  project   = google_project.fs.project_id
  bucket_id = google_app_engine_application.default-bucket-fs.default_bucket
}

# Creates a ruleset of Cloud Storage Security Rules from a local file.
resource "google_firebaserules_ruleset" "default-bucket-fs" {
  provider = google-beta
  project  = google_project.fs.project_id
  source {
    files {
      # Write security rules in a local file named "storage.rules".
      # Learn more: https://firebase.google.com/docs/storage/security/get-started
      name    = "storage.rules"
      content = file("storage.rules")
    }
  }

  # Wait for the Cloud Storage bucket to be provisioned before creating this ruleset.
  depends_on = [
    google_firebase_project.fs,
  ]
}

# Releases the ruleset to the default Storage bucket.
resource "google_firebaserules_release" "default-bucket-fs" {
  provider     = google-beta
  name         = "firebase.storage/${google_app_engine_application.default-bucket-fs.default_bucket}"
  ruleset_name = "projects/${google_project.fs.project_id}/rulesets/${google_firebaserules_ruleset.default-bucket-fs.name}"
  project      = google_project.fs.project_id
}

นี่คือชุดกฎของกฎความปลอดภัยของ Cloud Firestore ที่ควรอยู่ในไฟล์ในเครื่องชื่อ firestore.rules

rules_version = '2';
service cloud.firestore {
  match /databases/{database}/documents {
    allow read: if request.auth != null;
    allow create: if request.auth != null;
    allow update: if request.auth != null;
  }
}

นี่คือชุดกฎของกฎการรักษาความปลอดภัยของ Cloud Storage ที่ควรอยู่ในไฟล์ในเครื่องชื่อ storage.rules

rules_version = '2';
service firebase.storage {
  match /b/{bucket}/o {
    match /{allPaths=**} {
      allow read, write: if request.auth != null;
    }
  }
}

ปกป้องทรัพยากร API ด้วย Firebase App Check

การกำหนดค่านี้จะสร้างโปรเจ็กต์ Google Cloud ใหม่ เปิดใช้งานบริการ Firebase สำหรับโปรเจ็กต์ รวมถึงตั้งค่าและเปิดใช้การบังคับใช้ Firebase App Check สำหรับ Cloud Firestore เพื่อให้สามารถเข้าถึงได้จากแอป Android ของคุณเท่านั้น

# Creates a new Google Cloud project.
resource "google_project" "appcheck" {
  provider   = google-beta.no_user_project_override
  folder_id  = "folder-id-for-new-project"
  name       = "Project Display Name"
  project_id = "project-id-for-new-project"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "services" {
  provider = google-beta.no_user_project_override
  project  = google_project.appcheck.project_id
  for_each = toset([
    "cloudresourcemanager.googleapis.com",
    "firebase.googleapis.com",
    "firebaseappcheck.googleapis.com",
    "firestore.googleapis.com",
    "serviceusage.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created earlier.
resource "google_firebase_project" "appcheck" {
  provider = google-beta
  project  = google_project.appcheck.project_id

  depends_on = [google_project_service.services]
}

# Provisions the Firestore database instance.
resource "google_firestore_database" "database" {
  provider = google-beta
  project  = google_firebase_project.appcheck.project
  name     = "(default)"
  # See available locations: https://firebase.google.com/docs/projects/locations#default-cloud-location
  location_id = "name-of-region"
  # "FIRESTORE_NATIVE" is required to use Firestore with Firebase SDKs, authentication, and Firebase Security Rules.
  type             = "FIRESTORE_NATIVE"
  concurrency_mode = "OPTIMISTIC"

  # Wait for Firebase to be enabled in the Google Cloud project before initializing Firestore.
  depends_on = [
    google_firebase_project.appcheck,
  ]
}

# Creates a Firebase Android App in the new project created earlier.
resource "google_firebase_android_app" "appcheck" {
  provider     = google-beta
  project      = google_firebase_project.appcheck.project
  display_name = "Play Integrity app"
  package_name = "package.name.playintegrity"
  sha256_hashes = [
    # TODO: insert your Android app's SHA256 certificate
  ]
}

# It takes a while for App Check to recognize the new app
# If your app already exists, you don't have to wait 30 seconds.
resource "time_sleep" "wait_30s" {
  depends_on      = [google_firebase_android_app.appcheck]
  create_duration = "30s"
}

# Register the Android app with the Play Integrity provider
resource "google_firebase_app_check_play_integrity_config" "appcheck" {
  provider = google-beta
  project  = google_firebase_project.appcheck.project
  app_id   = google_firebase_android_app.appcheck.app_id

  depends_on = [time_sleep.wait_30s, google_firestore_database.database]

  lifecycle {
    precondition {
      condition     = length(google_firebase_android_app.appcheck.sha256_hashes) > 0
      error_message = "Provide a SHA-256 certificate on the Android App to use App Check"
    }
  }
}

# Enable enforcement of App Check for Firestore
resource "google_firebase_app_check_service_config" "firestore" {
  provider = google-beta

  project    = google_firebase_project.appcheck.project
  service_id = "firestore.googleapis.com"

  depends_on = [google_project_service.services]
}

ติดตั้งอินสแตนซ์ของส่วนขยาย Firebase

การกำหนดค่านี้จะสร้างโปรเจ็กต์ Google Cloud ใหม่ เปิดใช้บริการ Firebase สำหรับโปรเจ็กต์ และติดตั้งอินสแตนซ์ใหม่ของ Firebase Extension ในโปรเจ็กต์ หากมีอินสแตนซ์อยู่แล้ว พารามิเตอร์ของอินสแตนซ์จะได้รับการอัปเดตตามค่าที่ระบุในการกำหนดค่า

# Creates a new Google Cloud project.
resource "google_project" "extensions" {
  provider   = google-beta.no_user_project_override
  folder_id  = "folder-id-for-new-project"
  name       = "Project Display Name"
  project_id = "project-id-for-new-project"

  # Associates the project with a Cloud Billing account
  # (required to use Firebase Extensions).
  billing_account = "000000-000000-000000"

  # Required for the project to display in a list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "extensions" {
  provider = google-beta.no_user_project_override
  project  = google_project.extensions.project_id
  for_each = toset([
    "cloudbilling.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "serviceusage.googleapis.com",
    "firebase.googleapis.com",
    "firebaseextensions.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "extensions" {
  provider = google-beta
  project  = google_project.extensions.project_id

  depends_on = [
    google_project_service.extensions,
  ]
}

# Installs an instance of the "Translate Text in Firestore" extension.
# Or updates the extension if the specified instance already exists.
resource "google_firebase_extensions_instance" "translation" {
  provider = google-beta
  project = google_project.extensions.project_id

  instance_id = "translate-text-in-firestore"
  config {
    extension_ref = "firebase/firestore-translate-text"

    params = {
      COLLECTION_PATH      = "posts/comments/translations"
      DO_BACKFILL          = true
      LANGUAGES            = "ar,en,es,de,fr"
      INPUT_FIELD_NAME     = "input"
      LANGUAGES_FIELD_NAME = "languages"
      OUTPUT_FIELD_NAME    = "translated"
    }

    system_params = {
      "firebaseextensions.v1beta.function/location"                   = "us-central1"
      "firebaseextensions.v1beta.function/memory"                     = "256"
      "firebaseextensions.v1beta.function/minInstances"               = "0"
      "firebaseextensions.v1beta.function/vpcConnectorEgressSettings" = "VPC_CONNECTOR_EGRESS_SETTINGS_UNSPECIFIED"
    }
  }
}

คุณต้องการเรียนรู้เพิ่มเติมเกี่ยวกับแอตทริบิวต์ที่เกี่ยวข้องกับโครงการต่างๆ ทั้งหมด (เช่น project และ user_project_override )

คู่มือนี้ใช้แอตทริบิวต์ Terraform ต่อไปนี้เมื่อทำงานกับ "โครงการ"

project ภายในบล็อก resource

แนะนำ: ทุกครั้งที่เป็นไปได้ ให้รวมคุณลักษณะ project ไว้ในแต่ละบล็อก resource

ด้วยการรวมแอตทริบิวต์ของโครงการ Terraform จะสร้างโครงสร้างพื้นฐานที่ระบุในบล็อกทรัพยากรภายในโครงการที่ระบุ คู่มือนี้และไฟล์กำหนดค่าตัวอย่างของเราล้วนใช้แนวปฏิบัตินี้

ดูเอกสาร Terraform อย่างเป็นทางการเกี่ยวกับ project

user_project_override ภายในบล็อก provider

สำหรับการจัดสรรทรัพยากรส่วนใหญ่ คุณควรใช้ user_project_override = true ซึ่งหมายถึงการตรวจสอบโควต้ากับโปรเจ็กต์ Firebase ของคุณเอง อย่างไรก็ตาม หากต้องการตั้งค่าโปรเจ็กต์ใหม่ให้สามารถรับการตรวจสอบโควต้าได้ คุณต้องใช้ user_project_override = false ก่อน

ดูเอกสาร Terraform อย่างเป็นทางการเกี่ยวกับ user_project_override

คุณได้รับข้อผิดพลาดนี้: generic::permission_denied: Firebase Tos Not Accepted

ตรวจสอบให้แน่ใจว่าบัญชีผู้ใช้ที่คุณใช้เพื่อเรียกใช้คำสั่ง gCloud CLI ได้ยอมรับข้อกำหนดในการให้บริการของ Firebase (Firebase ToS) แล้ว

• คุณสามารถตรวจสอบได้โดยใช้เบราว์เซอร์ที่ลงชื่อเข้าใช้บัญชีผู้ใช้และพยายามดูโครงการ Firebase ที่มีอยู่ใน คอนโซล Firebase หากคุณสามารถดูโปรเจ็กต์ Firebase ที่มีอยู่ได้ แสดงว่าบัญชีผู้ใช้ได้ยอมรับ Firebase ToS แล้ว

• หากคุณไม่สามารถดูโปรเจ็กต์ Firebase ที่มีอยู่ได้ แสดงว่าบัญชีผู้ใช้อาจไม่ยอมรับ Firebase ToS หากต้องการแก้ไขปัญหานี้ ให้สร้างโปรเจ็กต์ Firebase ใหม่ผ่าน คอนโซล Firebase และยอมรับ Firebase ToS เป็นส่วนหนึ่งของการสร้างโปรเจ็กต์ คุณสามารถลบโปรเจ็กต์นี้ได้ทันทีผ่าน การตั้งค่าโปรเจ็กต์ ในคอนโซล

หลังจากรัน terraform apply คุณได้รับข้อผิดพลาดนี้: generic::permission_denied: IAM authority does not have the permission

รอสักครู่ แล้วลองเรียกใช้ terraform apply อีกครั้ง

การสร้างทรัพยากรล้มเหลว แต่เมื่อคุณเรียกใช้ terraform apply อีกครั้ง จะมีข้อความว่า ALREADY_EXISTS

อาจเนื่องมาจากความล่าช้าในการแพร่กระจายในระบบต่างๆ ลองแก้ไขปัญหานี้โดยการนำเข้าทรัพยากรเข้าสู่สถานะ Terraform โดยการเรียกใช้ terraform import จากนั้นลองรัน terraform apply อีกครั้ง

คุณสามารถเรียนรู้วิธีนำเข้าทรัพยากรแต่ละรายการได้ในส่วน "นำเข้า" ของเอกสาร Terraform (เช่น เอกสาร "นำเข้า" สำหรับ Cloud Firestore )

เมื่อทำงานกับ Cloud Firestore คุณได้รับข้อผิดพลาดนี้: Error creating Index: googleapi: Error 409;...Concurrent access -- try again

ตามข้อผิดพลาดที่แนะนำ Terraform อาจพยายามจัดเตรียมดัชนีหลายรายการและ/หรือสร้างเอกสารพร้อมกันและพบข้อผิดพลาดที่เกิดขึ้นพร้อมกัน ลองรัน terraform apply อีกครั้ง

คุณได้รับข้อผิดพลาด: "you may need to specify 'X-Goog-User-Project' HTTP header for quota and billing purposes"

ข้อผิดพลาดนี้หมายความว่า Terraform ไม่ทราบว่าควรตรวจสอบโควต้ากับโปรเจ็กต์ใด หากต้องการแก้ไขปัญหา ให้ตรวจสอบสิ่งต่อไปนี้ในบล็อก resource :

• ตรวจสอบให้แน่ใจว่าคุณได้ระบุค่าสำหรับแอตทริบิวต์ project
• ตรวจสอบให้แน่ใจว่าคุณใช้ผู้ให้บริการที่มี user_project_override = true (ไม่มีนามแฝง) ซึ่งในตัวอย่าง Firebase คือ google-beta

เมื่อสร้างโปรเจ็กต์ Google Cloud ใหม่ คุณได้รับข้อผิดพลาดว่ามีรหัสโปรเจ็กต์ที่ระบุสำหรับโปรเจ็กต์ใหม่อยู่แล้ว

สาเหตุที่เป็นไปได้ที่รหัสโปรเจ็กต์อาจมีอยู่แล้วมีดังนี้

• โครงการที่เกี่ยวข้องกับ ID นั้นเป็นของบุคคลอื่น

  • วิธีแก้ไข: เลือกรหัสโปรเจ็กต์อื่น

• โครงการที่เกี่ยวข้องกับ ID นั้นถูกลบไปเมื่อเร็วๆ นี้ (อยู่ในสถานะ soft-delete)

  • วิธีแก้ไข: หากคุณคิดว่าโปรเจ็กต์ที่เกี่ยวข้องกับ ID เป็นของคุณ ให้ตรวจสอบสถานะของโปรเจ็กต์โดยใช้ projects.get REST API

• โครงการที่เกี่ยวข้องกับ ID นั้นมีอยู่อย่างถูกต้องภายใต้ผู้ใช้ปัจจุบัน สาเหตุที่เป็นไปได้สำหรับข้อผิดพลาดอาจเป็นเพราะ terraform apply ก่อนหน้านี้ถูกขัดจังหวะ

  • วิธีแก้ไข: รันคำสั่งต่อไปนี้:
    terraform import google_project.default PROJECT_ID แล้ว
    terraform import google_firebase_project.default PROJECT_ID

เมื่อพยายามจัดเตรียม Cloud Firestore จากนั้นไปที่ Cloud Storage (ผ่าน google_app_engine_application ) คุณได้รับข้อผิดพลาดนี้: Error: Error creating App Engine application: googleapi: Error 409: Cannot create Firestore database resource <resource-name> since it already exists at location <location-id>, alreadyExists

แอปพลิเคชัน App Engine ต้องมีอินสแตนซ์ Cloud Firestore แต่คุณสามารถมีอินสแตนซ์ Cloud Firestore ได้เพียง 1 รายการต่อโปรเจ็กต์ ดังนั้น ตามที่ข้อความแสดงข้อผิดพลาดแนะนำ หากคุณได้จัดเตรียมอินสแตนซ์ Cloud Firestore ของโปรเจ็กต์ไว้ในที่เดียวแล้ว App Engine จะเกิดข้อผิดพลาดหากคุณพยายามจัดเตรียมอินสแตนซ์ Cloud Firestore ในตำแหน่งอื่น App Engine คิดว่าคุณกำลังพยายาม "จัดสรรใหม่" อินสแตนซ์ Cloud Firestore ที่มีอยู่แล้ว

หากต้องการแก้ไขข้อผิดพลาดนี้ ให้ใช้ตำแหน่งเดียวกันสำหรับทั้ง Cloud Firestore และแอปพลิเคชัน App Engine หากคุณต้องการที่เก็บข้อมูล Cloud Storage ในตำแหน่งอื่นจาก Cloud Firestore คุณสามารถจัดเตรียมที่เก็บข้อมูลเพิ่มเติมได้ (ดู การกำหนดค่าตัวอย่างสำหรับการสร้างที่เก็บข้อมูล Cloud Storage หลายรายการ )

เมื่อพยายามจัดเตรียม Cloud Storage (ผ่าน google_app_engine_application ) จากนั้น Cloud Firestore คุณได้รับข้อผิดพลาดนี้: Error: Error creating Database: googleapi: Error 409: Database already exists. Please use another database_id

เมื่อคุณจัดสรรที่เก็บข้อมูล Cloud Storage เริ่มต้นของโปรเจ็กต์ (ผ่าน google_app_engine_application ) และโปรเจ็กต์ยังไม่มีอินสแตนซ์ Cloud Firestore ดังนั้น google_app_engine_application จะจัดเตรียมอินสแตนซ์ Cloud Firestore ของโปรเจ็กต์โดยอัตโนมัติ

ดังนั้น หากอินสแตนซ์ Cloud Firestore ของโปรเจ็กต์ของคุณได้รับการจัดสรรแล้ว google_firestore_database จะเกิดข้อผิดพลาดหากคุณพยายามจัดเตรียมอินสแตนซ์ Cloud Firestore อย่างชัดเจน

เมื่อจัดสรรอินสแตนซ์ Cloud Firestore ของโปรเจ็กต์แล้ว คุณจะ "จัดสรรใหม่" หรือเปลี่ยนตำแหน่งของอินสแตนซ์ไม่ได้ หากต้องการหยุดไม่ให้ข้อผิดพลาดเกิดขึ้น ให้ลบบล็อกทรัพยากร google_firestore_database ออกจากไฟล์กำหนดค่าของคุณ อย่างไรก็ตาม โปรดทราบว่าเราแนะนำให้จัดสรร Cloud Firestore ก่อนที่เก็บข้อมูล Cloud Storage เริ่มต้นของโปรเจ็กต์ (ดูสาเหตุด้านล่างด้านล่าง)